home *** CD-ROM | disk | FTP | other *** search
/ Personal Computer World 2009 February / PCWFEB09.iso / Software / Linux / Kubuntu 8.10 / kubuntu-8.10-desktop-i386.iso / casper / filesystem.squashfs / usr / share / perl5 / HTML / Template.pm < prev    next >
Text File  |  2007-09-20  |  120KB  |  3,443 lines
  1. package HTML::Template;
  2.  
  3. $HTML::Template::VERSION = '2.9';
  4.  
  5. =head1 NAME
  6.  
  7. HTML::Template - Perl module to use HTML Templates from CGI scripts
  8.  
  9. =head1 SYNOPSIS
  10.  
  11. First you make a template - this is just a normal HTML file with a few
  12. extra tags, the simplest being <TMPL_VAR>
  13.  
  14. For example, test.tmpl:
  15.  
  16.   <html>
  17.   <head><title>Test Template</title></head>
  18.   <body>
  19.   My Home Directory is <TMPL_VAR NAME=HOME>
  20.   <p>
  21.   My Path is set to <TMPL_VAR NAME=PATH>
  22.   </body>
  23.   </html>
  24.  
  25. Now create a small CGI program:
  26.  
  27.   #!/usr/bin/perl -w
  28.   use HTML::Template;
  29.  
  30.   # open the html template
  31.   my $template = HTML::Template->new(filename => 'test.tmpl');
  32.  
  33.   # fill in some parameters
  34.   $template->param(HOME => $ENV{HOME});
  35.   $template->param(PATH => $ENV{PATH});
  36.  
  37.   # send the obligatory Content-Type and print the template output
  38.   print "Content-Type: text/html\n\n", $template->output;
  39.  
  40. If all is well in the universe this should show something like this in
  41. your browser when visiting the CGI:
  42.  
  43.   My Home Directory is /home/some/directory
  44.   My Path is set to /bin;/usr/bin
  45.  
  46. =head1 DESCRIPTION
  47.  
  48. This module attempts to make using HTML templates simple and natural.
  49. It extends standard HTML with a few new HTML-esque tags - <TMPL_VAR>,
  50. <TMPL_LOOP>, <TMPL_INCLUDE>, <TMPL_IF>, <TMPL_ELSE> and <TMPL_UNLESS>.
  51. The file written with HTML and these new tags is called a template.
  52. It is usually saved separate from your script - possibly even created
  53. by someone else!  Using this module you fill in the values for the
  54. variables, loops and branches declared in the template.  This allows
  55. you to separate design - the HTML - from the data, which you generate
  56. in the Perl script.
  57.  
  58. This module is licensed under the GPL.  See the LICENSE section
  59. below for more details.
  60.  
  61. =head1 TUTORIAL
  62.  
  63. If you're new to HTML::Template, I suggest you start with the
  64. introductory article available on the HTML::Template website:
  65.  
  66.    http://html-template.sourceforge.net
  67.  
  68. =head1 MOTIVATION
  69.  
  70. It is true that there are a number of packages out there to do HTML
  71. templates.  On the one hand you have things like HTML::Embperl which
  72. allows you freely mix Perl with HTML.  On the other hand lie
  73. home-grown variable substitution solutions.  Hopefully the module can
  74. find a place between the two.
  75.  
  76. One advantage of this module over a full HTML::Embperl-esque solution
  77. is that it enforces an important divide - design and programming.  By
  78. limiting the programmer to just using simple variables and loops in
  79. the HTML, the template remains accessible to designers and other
  80. non-perl people.  The use of HTML-esque syntax goes further to make
  81. the format understandable to others.  In the future this similarity
  82. could be used to extend existing HTML editors/analyzers to support
  83. HTML::Template.
  84.  
  85. An advantage of this module over home-grown tag-replacement schemes is
  86. the support for loops.  In my work I am often called on to produce
  87. tables of data in html.  Producing them using simplistic HTML
  88. templates results in CGIs containing lots of HTML since the HTML
  89. itself cannot represent loops.  The introduction of loop statements in
  90. the HTML simplifies this situation considerably.  The designer can
  91. layout a single row and the programmer can fill it in as many times as
  92. necessary - all they must agree on is the parameter names.
  93.  
  94. For all that, I think the best thing about this module is that it does
  95. just one thing and it does it quickly and carefully.  It doesn't try
  96. to replace Perl and HTML, it just augments them to interact a little
  97. better.  And it's pretty fast.
  98.  
  99. =head1 THE TAGS
  100.  
  101. =head2 TMPL_VAR
  102.  
  103.   <TMPL_VAR NAME="PARAMETER_NAME">
  104.  
  105. The <TMPL_VAR> tag is very simple.  For each <TMPL_VAR> tag in the
  106. template you call $template->param(PARAMETER_NAME => "VALUE").  When
  107. the template is output the <TMPL_VAR> is replaced with the VALUE text
  108. you specified.  If you don't set a parameter it just gets skipped in
  109. the output.
  110.  
  111. Optionally you can use the "ESCAPE=HTML" option in the tag to indicate
  112. that you want the value to be HTML-escaped before being returned from
  113. output (the old ESCAPE=1 syntax is still supported).  This means that
  114. the ", <, >, and & characters get translated into ", <, >
  115. and & respectively.  This is useful when you want to use a
  116. TMPL_VAR in a context where those characters would cause trouble.
  117. Example:
  118.  
  119.    <input name=param type=text value="<TMPL_VAR NAME="PARAM">">
  120.  
  121. If you called C<param()> with a value like sam"my you'll get in trouble
  122. with HTML's idea of a double-quote.  On the other hand, if you use
  123. ESCAPE=HTML, like this:
  124.  
  125.    <input name=param type=text value="<TMPL_VAR ESCAPE=HTML NAME="PARAM">">
  126.  
  127. You'll get what you wanted no matter what value happens to be passed in for
  128. param.  You can also write ESCAPE="HTML", ESCAPE='HTML' and ESCAPE='1'.
  129.  
  130. "ESCAPE=0" and "ESCAPE=NONE" turn off escaping, which is the default
  131. behavior.
  132.  
  133. There is also the "ESCAPE=URL" option which may be used for VARs that
  134. populate a URL.  It will do URL escaping, like replacing ' ' with '+'
  135. and '/' with '%2F'.
  136.  
  137. There is also the "ESCAPE=JS" option which may be used for VARs that
  138. need to be placed within a Javascript string. All \n, \r, ' and " characters
  139. are escaped.
  140.  
  141. You can assign a default value to a variable with the DEFAULT
  142. attribute.  For example, this will output "the devil gave me a taco"
  143. if the "who" variable is not set.
  144.  
  145.   The <TMPL_VAR NAME=WHO DEFAULT=devil> gave me a taco.
  146.  
  147. =head2 TMPL_LOOP
  148.  
  149.   <TMPL_LOOP NAME="LOOP_NAME"> ... </TMPL_LOOP>
  150.  
  151. The <TMPL_LOOP> tag is a bit more complicated than <TMPL_VAR>.  The
  152. <TMPL_LOOP> tag allows you to delimit a section of text and give it a
  153. name.  Inside this named loop you place <TMPL_VAR>s.  Now you pass to
  154. C<param()> a list (an array ref) of parameter assignments (hash refs) for
  155. this loop.  The loop iterates over the list and produces output from
  156. the text block for each pass.  Unset parameters are skipped.  Here's
  157. an example:
  158.  
  159.  In the template:
  160.  
  161.    <TMPL_LOOP NAME=EMPLOYEE_INFO>
  162.       Name: <TMPL_VAR NAME=NAME> <br>
  163.       Job:  <TMPL_VAR NAME=JOB>  <p>
  164.    </TMPL_LOOP>
  165.  
  166.  
  167.  In the script:
  168.  
  169.    $template->param(EMPLOYEE_INFO => [ 
  170.                                        { name => 'Sam', job => 'programmer' },
  171.                                        { name => 'Steve', job => 'soda jerk' },
  172.                                      ]
  173.                    );
  174.    print $template->output();
  175.  
  176.   
  177.  The output in a browser:
  178.  
  179.    Name: Sam
  180.    Job: programmer
  181.  
  182.    Name: Steve
  183.    Job: soda jerk
  184.  
  185. As you can see above the <TMPL_LOOP> takes a list of variable
  186. assignments and then iterates over the loop body producing output.
  187.  
  188. Often you'll want to generate a <TMPL_LOOP>'s contents
  189. programmatically.  Here's an example of how this can be done (many
  190. other ways are possible!):
  191.  
  192.    # a couple of arrays of data to put in a loop:
  193.    my @words = qw(I Am Cool);
  194.    my @numbers = qw(1 2 3);
  195.  
  196.    my @loop_data = ();  # initialize an array to hold your loop
  197.  
  198.    while (@words and @numbers) {
  199.      my %row_data;  # get a fresh hash for the row data
  200.  
  201.      # fill in this row
  202.      $row_data{WORD} = shift @words;
  203.      $row_data{NUMBER} = shift @numbers;
  204.  
  205.      # the crucial step - push a reference to this row into the loop!
  206.      push(@loop_data, \%row_data);
  207.    }
  208.  
  209.    # finally, assign the loop data to the loop param, again with a
  210.    # reference:
  211.    $template->param(THIS_LOOP => \@loop_data);
  212.  
  213. The above example would work with a template like:
  214.  
  215.    <TMPL_LOOP NAME="THIS_LOOP">
  216.       Word: <TMPL_VAR NAME="WORD">     <br>
  217.       Number: <TMPL_VAR NAME="NUMBER"> <p>
  218.    </TMPL_LOOP>
  219.  
  220. It would produce output like:
  221.  
  222.    Word: I
  223.    Number: 1
  224.  
  225.    Word: Am
  226.    Number: 2
  227.  
  228.    Word: Cool
  229.    Number: 3
  230.  
  231. <TMPL_LOOP>s within <TMPL_LOOP>s are fine and work as you would
  232. expect.  If the syntax for the C<param()> call has you stumped, here's an
  233. example of a param call with one nested loop:
  234.  
  235.   $template->param(LOOP => [
  236.                             { name => 'Bobby',
  237.                               nicknames => [
  238.                                             { name => 'the big bad wolf' }, 
  239.                                             { name => 'He-Man' },
  240.                                            ],
  241.                             },
  242.                            ],
  243.                   );
  244.  
  245. Basically, each <TMPL_LOOP> gets an array reference.  Inside the array
  246. are any number of hash references.  These hashes contain the
  247. name=>value pairs for a single pass over the loop template.  
  248.  
  249. Inside a <TMPL_LOOP>, the only variables that are usable are the ones
  250. from the <TMPL_LOOP>.  The variables in the outer blocks are not
  251. visible within a template loop.  For the computer-science geeks among
  252. you, a <TMPL_LOOP> introduces a new scope much like a perl subroutine
  253. call.  If you want your variables to be global you can use
  254. 'global_vars' option to new() described below.
  255.  
  256. =head2 TMPL_INCLUDE
  257.  
  258.   <TMPL_INCLUDE NAME="filename.tmpl">
  259.  
  260. This tag includes a template directly into the current template at the
  261. point where the tag is found.  The included template contents are used
  262. exactly as if its contents were physically included in the master
  263. template.
  264.  
  265. The file specified can be an absolute path (beginning with a '/' under
  266. Unix, for example).  If it isn't absolute, the path to the enclosing
  267. file is tried first.  After that the path in the environment variable
  268. HTML_TEMPLATE_ROOT is tried, if it exists.  Next, the "path" option is
  269. consulted, first as-is and then with HTML_TEMPLATE_ROOT prepended if
  270. available.  As a final attempt, the filename is passed to open()
  271. directly.  See below for more information on HTML_TEMPLATE_ROOT and
  272. the "path" option to new().
  273.  
  274. As a protection against infinitly recursive includes, an arbitary
  275. limit of 10 levels deep is imposed.  You can alter this limit with the
  276. "max_includes" option.  See the entry for the "max_includes" option
  277. below for more details.
  278.  
  279. =head2 TMPL_IF
  280.  
  281.   <TMPL_IF NAME="PARAMETER_NAME"> ... </TMPL_IF>
  282.  
  283. The <TMPL_IF> tag allows you to include or not include a block of the
  284. template based on the value of a given parameter name.  If the
  285. parameter is given a value that is true for Perl - like '1' - then the
  286. block is included in the output.  If it is not defined, or given a
  287. false value - like '0' - then it is skipped.  The parameters are
  288. specified the same way as with TMPL_VAR.
  289.  
  290. Example Template:
  291.  
  292.    <TMPL_IF NAME="BOOL">
  293.      Some text that only gets displayed if BOOL is true!
  294.    </TMPL_IF>
  295.  
  296. Now if you call $template->param(BOOL => 1) then the above block will
  297. be included by output. 
  298.  
  299. <TMPL_IF> </TMPL_IF> blocks can include any valid HTML::Template
  300. construct - VARs and LOOPs and other IF/ELSE blocks.  Note, however,
  301. that intersecting a <TMPL_IF> and a <TMPL_LOOP> is invalid.
  302.  
  303.    Not going to work:
  304.    <TMPL_IF BOOL>
  305.       <TMPL_LOOP SOME_LOOP>
  306.    </TMPL_IF>
  307.       </TMPL_LOOP>
  308.  
  309. If the name of a TMPL_LOOP is used in a TMPL_IF, the IF block will
  310. output if the loop has at least one row.  Example:
  311.  
  312.   <TMPL_IF LOOP_ONE>
  313.     This will output if the loop is not empty.
  314.   </TMPL_IF>
  315.  
  316.   <TMPL_LOOP LOOP_ONE>
  317.     ....
  318.   </TMPL_LOOP>
  319.  
  320. WARNING: Much of the benefit of HTML::Template is in decoupling your
  321. Perl and HTML.  If you introduce numerous cases where you have
  322. TMPL_IFs and matching Perl if()s, you will create a maintenance
  323. problem in keeping the two synchronized.  I suggest you adopt the
  324. practice of only using TMPL_IF if you can do so without requiring a
  325. matching if() in your Perl code.
  326.  
  327. =head2 TMPL_ELSE
  328.  
  329.   <TMPL_IF NAME="PARAMETER_NAME"> ... <TMPL_ELSE> ... </TMPL_IF>
  330.  
  331. You can include an alternate block in your TMPL_IF block by using
  332. TMPL_ELSE.  NOTE: You still end the block with </TMPL_IF>, not
  333. </TMPL_ELSE>!
  334.  
  335.    Example:
  336.  
  337.    <TMPL_IF BOOL>
  338.      Some text that is included only if BOOL is true
  339.    <TMPL_ELSE>
  340.      Some text that is included only if BOOL is false
  341.    </TMPL_IF>
  342.  
  343. =head2 TMPL_UNLESS
  344.  
  345.   <TMPL_UNLESS NAME="PARAMETER_NAME"> ... </TMPL_UNLESS>
  346.  
  347. This tag is the opposite of <TMPL_IF>.  The block is output if the
  348. CONTROL_PARAMETER is set false or not defined.  You can use
  349. <TMPL_ELSE> with <TMPL_UNLESS> just as you can with <TMPL_IF>.
  350.  
  351.   Example:
  352.  
  353.   <TMPL_UNLESS BOOL>
  354.     Some text that is output only if BOOL is FALSE.
  355.   <TMPL_ELSE>
  356.     Some text that is output only if BOOL is TRUE.
  357.   </TMPL_UNLESS>
  358.  
  359. If the name of a TMPL_LOOP is used in a TMPL_UNLESS, the UNLESS block
  360. output if the loop has zero rows.
  361.  
  362.   <TMPL_UNLESS LOOP_ONE>
  363.     This will output if the loop is empty.
  364.   </TMPL_UNLESS>
  365.   
  366.   <TMPL_LOOP LOOP_ONE>
  367.     ....
  368.   </TMPL_LOOP>
  369.  
  370. =cut
  371.  
  372. =head2 NOTES
  373.  
  374. HTML::Template's tags are meant to mimic normal HTML tags.  However,
  375. they are allowed to "break the rules".  Something like:
  376.  
  377.    <img src="<TMPL_VAR IMAGE_SRC>">
  378.  
  379. is not really valid HTML, but it is a perfectly valid use and will
  380. work as planned.
  381.  
  382. The "NAME=" in the tag is optional, although for extensibility's sake I
  383. recommend using it.  Example - "<TMPL_LOOP LOOP_NAME>" is acceptable.
  384.  
  385. If you're a fanatic about valid HTML and would like your templates
  386. to conform to valid HTML syntax, you may optionally type template tags
  387. in the form of HTML comments. This may be of use to HTML authors who
  388. would like to validate their templates' HTML syntax prior to
  389. HTML::Template processing, or who use DTD-savvy editing tools.
  390.  
  391.   <!-- TMPL_VAR NAME=PARAM1 -->
  392.  
  393. In order to realize a dramatic savings in bandwidth, the standard
  394. (non-comment) tags will be used throughout this documentation.
  395.  
  396. =head1 METHODS
  397.  
  398. =head2 new()
  399.  
  400. Call new() to create a new Template object:
  401.  
  402.   my $template = HTML::Template->new( filename => 'file.tmpl', 
  403.                                       option => 'value' 
  404.                                     );
  405.  
  406. You must call new() with at least one name => value pair specifying how
  407. to access the template text.  You can use C<< filename => 'file.tmpl' >> 
  408. to specify a filename to be opened as the template.  Alternately you can
  409. use:
  410.  
  411.   my $t = HTML::Template->new( scalarref => $ref_to_template_text, 
  412.                                option => 'value' 
  413.                              );
  414.  
  415. and
  416.  
  417.   my $t = HTML::Template->new( arrayref => $ref_to_array_of_lines , 
  418.                                option => 'value' 
  419.                              );
  420.  
  421.  
  422. These initialize the template from in-memory resources.  In almost
  423. every case you'll want to use the filename parameter.  If you're
  424. worried about all the disk access from reading a template file just
  425. use mod_perl and the cache option detailed below.
  426.  
  427. You can also read the template from an already opened filehandle,
  428. either traditionally as a glob or as a FileHandle:
  429.  
  430.   my $t = HTML::Template->new( filehandle => *FH, option => 'value');
  431.  
  432. The four new() calling methods can also be accessed as below, if you
  433. prefer.
  434.  
  435.   my $t = HTML::Template->new_file('file.tmpl', option => 'value');
  436.  
  437.   my $t = HTML::Template->new_scalar_ref($ref_to_template_text, 
  438.                                         option => 'value');
  439.  
  440.   my $t = HTML::Template->new_array_ref($ref_to_array_of_lines, 
  441.                                        option => 'value');
  442.  
  443.   my $t = HTML::Template->new_filehandle($fh, 
  444.                                        option => 'value');
  445.  
  446. And as a final option, for those that might prefer it, you can call new as:
  447.  
  448.   my $t = HTML::Template->new(type => 'filename', 
  449.                               source => 'file.tmpl');
  450.  
  451. Which works for all three of the source types.
  452.  
  453. If the environment variable HTML_TEMPLATE_ROOT is set and your
  454. filename doesn't begin with /, then the path will be relative to the
  455. value of $HTML_TEMPLATE_ROOT.  Example - if the environment variable
  456. HTML_TEMPLATE_ROOT is set to "/home/sam" and I call
  457. HTML::Template->new() with filename set to "sam.tmpl", the
  458. HTML::Template will try to open "/home/sam/sam.tmpl" to access the
  459. template file.  You can also affect the search path for files with the
  460. "path" option to new() - see below for more information.
  461.  
  462. You can modify the Template object's behavior with new().  The options
  463. are available:
  464.  
  465. =over 4
  466.  
  467. =item Error Detection Options
  468.  
  469. =over 4 
  470.  
  471. =item *
  472.  
  473. die_on_bad_params - if set to 0 the module will let you call
  474. $template->param(param_name => 'value') even if 'param_name' doesn't
  475. exist in the template body.  Defaults to 1.
  476.  
  477. =item *
  478.  
  479. force_untaint - if set to 1 the module will not allow you to set 
  480. unescaped parameters with tainted values. If set to 2 you will have 
  481. to untaint all parameters, including ones with the escape attribute.
  482. This option makes sure you untaint everything so you don't accidentally
  483. introduce e.g. cross-site-scripting (CSS) vulnerabilities. Requires 
  484. taint mode. Defaults to 0.
  485.  
  486. =item *
  487.  
  488. strict - if set to 0 the module will allow things that look like they
  489. might be TMPL_* tags to get by without dieing.  Example:
  490.  
  491.    <TMPL_HUH NAME=ZUH>
  492.  
  493. Would normally cause an error, but if you call new with strict => 0,
  494. HTML::Template will ignore it.  Defaults to 1.
  495.  
  496. =item *
  497.  
  498. vanguard_compatibility_mode - if set to 1 the module will expect to
  499. see <TMPL_VAR>s that look like %NAME% in addition to the standard
  500. syntax.  Also sets die_on_bad_params => 0.  If you're not at Vanguard
  501. Media trying to use an old format template don't worry about this one.
  502. Defaults to 0.
  503.  
  504. =back
  505.  
  506. =item Caching Options
  507.  
  508. =over 4
  509.  
  510. =item *
  511.  
  512. cache - if set to 1 the module will cache in memory the parsed
  513. templates based on the filename parameter and modification date of the
  514. file.  This only applies to templates opened with the filename
  515. parameter specified, not scalarref or arrayref templates.  Caching
  516. also looks at the modification times of any files included using
  517. <TMPL_INCLUDE> tags, but again, only if the template is opened with
  518. filename parameter.  
  519.  
  520. This is mainly of use in a persistent environment like
  521. Apache/mod_perl.  It has absolutely no benefit in a normal CGI
  522. environment since the script is unloaded from memory after every
  523. request.  For a cache that does work for normal CGIs see the
  524. 'shared_cache' option below.
  525.  
  526. Note that different new() parameter settings do not cause a cache
  527. refresh, only a change in the modification time of the template will
  528. trigger a cache refresh.  For most usages this is fine.  My simplistic
  529. testing shows that using cache yields a 90% performance increase under
  530. mod_perl.  Cache defaults to 0.
  531.  
  532. =item *
  533.  
  534. shared_cache - if set to 1 the module will store its cache in shared
  535. memory using the IPC::SharedCache module (available from CPAN).  The
  536. effect of this will be to maintain a single shared copy of each parsed
  537. template for all instances of HTML::Template to use.  This can be a
  538. significant reduction in memory usage in a multiple server
  539. environment.  As an example, on one of our systems we use 4MB of
  540. template cache and maintain 25 httpd processes - shared_cache results
  541. in saving almost 100MB!  Of course, some reduction in speed versus
  542. normal caching is to be expected.  Another difference between normal
  543. caching and shared_cache is that shared_cache will work in a CGI
  544. environment - normal caching is only useful in a persistent
  545. environment like Apache/mod_perl.
  546.  
  547. By default HTML::Template uses the IPC key 'TMPL' as a shared root
  548. segment (0x4c504d54 in hex), but this can be changed by setting the
  549. 'ipc_key' new() parameter to another 4-character or integer key.
  550. Other options can be used to affect the shared memory cache correspond
  551. to IPC::SharedCache options - ipc_mode, ipc_segment_size and
  552. ipc_max_size.  See L<IPC::SharedCache> for a description of how these
  553. work - in most cases you shouldn't need to change them from the
  554. defaults.
  555.  
  556. For more information about the shared memory cache system used by
  557. HTML::Template see L<IPC::SharedCache>.
  558.  
  559. =item *
  560.  
  561. double_cache - if set to 1 the module will use a combination of
  562. shared_cache and normal cache mode for the best possible caching.  Of
  563. course, it also uses the most memory of all the cache modes.  All the
  564. same ipc_* options that work with shared_cache apply to double_cache
  565. as well.  By default double_cache is off.
  566.  
  567. =item *
  568.  
  569. blind_cache - if set to 1 the module behaves exactly as with normal
  570. caching but does not check to see if the file has changed on each
  571. request.  This option should be used with caution, but could be of use
  572. on high-load servers.  My tests show blind_cache performing only 1 to
  573. 2 percent faster than cache under mod_perl.
  574.  
  575. NOTE: Combining this option with shared_cache can result in stale
  576. templates stuck permanently in shared memory!
  577.  
  578. =item *
  579.  
  580. file_cache - if set to 1 the module will store its cache in a file
  581. using the Storable module.  It uses no additional memory, and my
  582. simplistic testing shows that it yields a 50% performance advantage.
  583. Like shared_cache, it will work in a CGI environment. Default is 0.
  584.  
  585. If you set this option you must set the "file_cache_dir" option.  See
  586. below for details.
  587.  
  588. NOTE: Storable using flock() to ensure safe access to cache files.
  589. Using file_cache on a system or filesystem (NFS) without flock()
  590. support is dangerous.
  591.  
  592.  
  593. =item *
  594.  
  595. file_cache_dir - sets the directory where the module will store the
  596. cache files if file_cache is enabled.  Your script will need write
  597. permissions to this directory.  You'll also need to make sure the
  598. sufficient space is available to store the cache files.
  599.  
  600. =item *
  601.  
  602. file_cache_dir_mode - sets the file mode for newly created file_cache
  603. directories and subdirectories.  Defaults to 0700 for security but
  604. this may be inconvenient if you do not have access to the account
  605. running the webserver.
  606.  
  607. =item *
  608.  
  609. double_file_cache - if set to 1 the module will use a combination of
  610. file_cache and normal cache mode for the best possible caching.  The
  611. file_cache_* options that work with file_cache apply to double_file_cache
  612. as well.  By default double_file_cache is 0.
  613.  
  614. =back
  615.  
  616. =item Filesystem Options
  617.  
  618. =over 4
  619.  
  620. =item *
  621.  
  622. path - you can set this variable with a list of paths to search for
  623. files specified with the "filename" option to new() and for files
  624. included with the <TMPL_INCLUDE> tag.  This list is only consulted
  625. when the filename is relative.  The HTML_TEMPLATE_ROOT environment
  626. variable is always tried first if it exists.  Also, if
  627. HTML_TEMPLATE_ROOT is set then an attempt will be made to prepend
  628. HTML_TEMPLATE_ROOT onto paths in the path array.  In the case of a
  629. <TMPL_INCLUDE> file, the path to the including file is also tried
  630. before path is consulted.
  631.  
  632. Example:
  633.  
  634.    my $template = HTML::Template->new( filename => 'file.tmpl',
  635.                                        path => [ '/path/to/templates',
  636.                                                  '/alternate/path'
  637.                                                ]
  638.                                       );
  639.  
  640. NOTE: the paths in the path list must be expressed as UNIX paths,
  641. separated by the forward-slash character ('/').
  642.  
  643. =item *
  644.  
  645. search_path_on_include - if set to a true value the module will search
  646. from the top of the array of paths specified by the path option on
  647. every <TMPL_INCLUDE> and use the first matching template found.  The
  648. normal behavior is to look only in the current directory for a
  649. template to include.  Defaults to 0.
  650.  
  651. =back
  652.  
  653. =item Debugging Options
  654.  
  655. =over 4
  656.  
  657. =item *
  658.  
  659. debug - if set to 1 the module will write random debugging information
  660. to STDERR.  Defaults to 0.
  661.  
  662. =item *
  663.  
  664. stack_debug - if set to 1 the module will use Data::Dumper to print
  665. out the contents of the parse_stack to STDERR.  Defaults to 0.
  666.  
  667. =item *
  668.  
  669. cache_debug - if set to 1 the module will send information on cache
  670. loads, hits and misses to STDERR.  Defaults to 0.
  671.  
  672. =item *
  673.  
  674. shared_cache_debug - if set to 1 the module will turn on the debug
  675. option in IPC::SharedCache - see L<IPC::SharedCache> for
  676. details. Defaults to 0.
  677.  
  678. =item *
  679.  
  680. memory_debug - if set to 1 the module will send information on cache
  681. memory usage to STDERR.  Requires the GTop module.  Defaults to 0.
  682.  
  683. =back
  684.  
  685. =item Miscellaneous Options
  686.  
  687. =over 4
  688.  
  689. =item *
  690.  
  691. associate - this option allows you to inherit the parameter values
  692. from other objects.  The only requirement for the other object is that
  693. it have a C<param()> method that works like HTML::Template's C<param()>.  A
  694. good candidate would be a CGI.pm query object.  Example:
  695.  
  696.   my $query = new CGI;
  697.   my $template = HTML::Template->new(filename => 'template.tmpl',
  698.                                      associate => $query);
  699.  
  700. Now, C<< $template->output() >> will act as though
  701.  
  702.   $template->param('FormField', $cgi->param('FormField'));
  703.  
  704. had been specified for each key/value pair that would be provided by
  705. the C<< $cgi->param() >> method.  Parameters you set directly take
  706. precedence over associated parameters.
  707.  
  708. You can specify multiple objects to associate by passing an anonymous
  709. array to the associate option.  They are searched for parameters in
  710. the order they appear:
  711.  
  712.   my $template = HTML::Template->new(filename => 'template.tmpl',
  713.                                      associate => [$query, $other_obj]);
  714.  
  715. The old associateCGI() call is still supported, but should be
  716. considered obsolete.
  717.  
  718. NOTE: The parameter names are matched in a case-insensitve manner.  If
  719. you have two parameters in a CGI object like 'NAME' and 'Name' one
  720. will be chosen randomly by associate.  This behavior can be changed by
  721. the following option.
  722.  
  723. =item *
  724.  
  725. case_sensitive - setting this option to true causes HTML::Template to
  726. treat template variable names case-sensitively.  The following example
  727. would only set one parameter without the "case_sensitive" option:
  728.  
  729.   my $template = HTML::Template->new(filename => 'template.tmpl',
  730.                                      case_sensitive => 1);
  731.   $template->param(
  732.     FieldA => 'foo',
  733.     fIELDa => 'bar',
  734.   );
  735.  
  736. This option defaults to off.
  737.  
  738. NOTE: with case_sensitive and loop_context_vars the special loop
  739. variables are available in lower-case only.
  740.  
  741. =item *
  742.  
  743. loop_context_vars - when this parameter is set to true (it is false by
  744. default) four loop context variables are made available inside a loop:
  745. __first__, __last__, __inner__, __odd__.  They can be used with
  746. <TMPL_IF>, <TMPL_UNLESS> and <TMPL_ELSE> to control how a loop is
  747. output.  
  748.  
  749. In addition to the above, a __counter__ var is also made available
  750. when loop context variables are turned on.
  751.  
  752. Example:
  753.  
  754.    <TMPL_LOOP NAME="FOO">
  755.       <TMPL_IF NAME="__first__">
  756.         This only outputs on the first pass.
  757.       </TMPL_IF>
  758.  
  759.       <TMPL_IF NAME="__odd__">
  760.         This outputs every other pass, on the odd passes.
  761.       </TMPL_IF>
  762.  
  763.       <TMPL_UNLESS NAME="__odd__">
  764.         This outputs every other pass, on the even passes.
  765.       </TMPL_UNLESS>
  766.  
  767.       <TMPL_IF NAME="__inner__">
  768.         This outputs on passes that are neither first nor last.
  769.       </TMPL_IF>
  770.  
  771.       This is pass number <TMPL_VAR NAME="__counter__">.
  772.  
  773.       <TMPL_IF NAME="__last__">
  774.         This only outputs on the last pass.
  775.       </TMPL_IF>
  776.    </TMPL_LOOP>
  777.  
  778. One use of this feature is to provide a "separator" similar in effect
  779. to the perl function join().  Example:
  780.  
  781.    <TMPL_LOOP FRUIT>
  782.       <TMPL_IF __last__> and </TMPL_IF>
  783.       <TMPL_VAR KIND><TMPL_UNLESS __last__>, <TMPL_ELSE>.</TMPL_UNLESS>
  784.    </TMPL_LOOP>
  785.  
  786. Would output (in a browser) something like:
  787.  
  788.   Apples, Oranges, Brains, Toes, and Kiwi.
  789.  
  790. Given an appropriate C<param()> call, of course.  NOTE: A loop with only
  791. a single pass will get both __first__ and __last__ set to true, but
  792. not __inner__.
  793.  
  794. =item *
  795.  
  796. no_includes - set this option to 1 to disallow the <TMPL_INCLUDE> tag
  797. in the template file.  This can be used to make opening untrusted
  798. templates B<slightly> less dangerous.  Defaults to 0.
  799.  
  800. =item *
  801.  
  802. max_includes - set this variable to determine the maximum depth that
  803. includes can reach.  Set to 10 by default.  Including files to a depth
  804. greater than this value causes an error message to be displayed.  Set
  805. to 0 to disable this protection.
  806.  
  807. =item *
  808.  
  809. global_vars - normally variables declared outside a loop are not
  810. available inside a loop.  This option makes <TMPL_VAR>s like global
  811. variables in Perl - they have unlimited scope.  This option also
  812. affects <TMPL_IF> and <TMPL_UNLESS>.
  813.  
  814. Example:
  815.  
  816.   This is a normal variable: <TMPL_VAR NORMAL>.<P>
  817.  
  818.   <TMPL_LOOP NAME=FROOT_LOOP>
  819.      Here it is inside the loop: <TMPL_VAR NORMAL><P>
  820.   </TMPL_LOOP>
  821.  
  822. Normally this wouldn't work as expected, since <TMPL_VAR NORMAL>'s
  823. value outside the loop is not available inside the loop.
  824.  
  825. The global_vars option also allows you to access the values of an
  826. enclosing loop within an inner loop.  For example, in this loop the
  827. inner loop will have access to the value of OUTER_VAR in the correct
  828. iteration:
  829.  
  830.    <TMPL_LOOP OUTER_LOOP>
  831.       OUTER: <TMPL_VAR OUTER_VAR>
  832.         <TMPL_LOOP INNER_LOOP>
  833.            INNER: <TMPL_VAR INNER_VAR>
  834.            INSIDE OUT: <TMPL_VAR OUTER_VAR>
  835.         </TMPL_LOOP>
  836.    </TMPL_LOOP>
  837.  
  838. One side-effect of global-vars is that variables you set with param()
  839. that might otherwise be ignored when die_on_bad_params is off will
  840. stick around.  This is necessary to allow inner loops to access values
  841. set for outer loops that don't directly use the value.
  842.  
  843. B<NOTE>: C<global_vars> is not C<global_loops> (which does not exist).
  844. That means that loops you declare at one scope are not available
  845. inside other loops even when C<global_vars> is on.
  846.  
  847. =item *
  848.  
  849. filter - this option allows you to specify a filter for your template
  850. files.  A filter is a subroutine that will be called after
  851. HTML::Template reads your template file but before it starts parsing
  852. template tags.
  853.  
  854. In the most simple usage, you simply assign a code reference to the
  855. filter parameter.  This subroutine will recieve a single argument - a
  856. reference to a string containing the template file text.  Here is an
  857. example that accepts templates with tags that look like "!!!ZAP_VAR
  858. FOO!!!" and transforms them into HTML::Template tags:
  859.  
  860.    my $filter = sub {
  861.      my $text_ref = shift;
  862.      $$text_ref =~ s/!!!ZAP_(.*?)!!!/<TMPL_$1>/g;
  863.    };
  864.  
  865.    # open zap.tmpl using the above filter
  866.    my $template = HTML::Template->new(filename => 'zap.tmpl',
  867.                                       filter => $filter);
  868.  
  869. More complicated usages are possible.  You can request that your
  870. filter receieve the template text as an array of lines rather than as
  871. a single scalar.  To do that you need to specify your filter using a
  872. hash-ref.  In this form you specify the filter using the C<sub> key and
  873. the desired argument format using the C<format> key.  The available
  874. formats are C<scalar> and C<array>.  Using the C<array> format will incur
  875. a performance penalty but may be more convenient in some situations.
  876.  
  877.    my $template = HTML::Template->new(filename => 'zap.tmpl',
  878.                                       filter => { sub => $filter,
  879.                                                   format => 'array' });
  880.  
  881. You may also have multiple filters.  This allows simple filters to be
  882. combined for more elaborate functionality.  To do this you specify an
  883. array of filters.  The filters are applied in the order they are
  884. specified.
  885.  
  886.    my $template = HTML::Template->new(filename => 'zap.tmpl',
  887.                                       filter => [ 
  888.                                            { sub => \&decompress,
  889.                                              format => 'scalar' },
  890.                                            { sub => \&remove_spaces,
  891.                                              format => 'array' }
  892.                                         ]);
  893.  
  894. The specified filters will be called for any TMPL_INCLUDEed files just
  895. as they are for the main template file.
  896.  
  897. =item * 
  898.  
  899. default_escape - Set this parameter to "HTML", "URL" or "JS" and
  900. HTML::Template will apply the specified escaping to all variables
  901. unless they declare a different escape in the template.
  902.  
  903. =back
  904.  
  905. =back 4
  906.  
  907. =cut
  908.  
  909.  
  910. use integer; # no floating point math so far!
  911. use strict; # and no funny business, either.
  912.  
  913. use Carp; # generate better errors with more context
  914. use File::Spec; # generate paths that work on all platforms
  915. use Digest::MD5 qw(md5_hex); # generate cache keys
  916. use Scalar::Util qw(tainted);
  917.  
  918. # define accessor constants used to improve readability of array
  919. # accesses into "objects".  I used to use 'use constant' but that
  920. # seems to cause occasional irritating warnings in older Perls.
  921. package HTML::Template::LOOP;
  922. sub TEMPLATE_HASH () { 0 };
  923. sub PARAM_SET     () { 1 };
  924.  
  925. package HTML::Template::COND;
  926. sub VARIABLE           () { 0 };
  927. sub VARIABLE_TYPE      () { 1 };
  928. sub VARIABLE_TYPE_VAR  () { 0 };
  929. sub VARIABLE_TYPE_LOOP () { 1 };
  930. sub JUMP_IF_TRUE       () { 2 };
  931. sub JUMP_ADDRESS       () { 3 };
  932. sub WHICH              () { 4 };
  933. sub UNCONDITIONAL_JUMP () { 5 };
  934. sub IS_ELSE            () { 6 };
  935. sub WHICH_IF           () { 0 };
  936. sub WHICH_UNLESS       () { 1 };
  937.  
  938. # back to the main package scope.
  939. package HTML::Template;
  940.  
  941. # open a new template and return an object handle
  942. sub new {
  943.   my $pkg = shift;
  944.   my $self; { my %hash; $self = bless(\%hash, $pkg); }
  945.  
  946.   # the options hash
  947.   my $options = {};
  948.   $self->{options} = $options;
  949.  
  950.   # set default parameters in options hash
  951.   %$options = (
  952.                debug => 0,
  953.                stack_debug => 0,
  954.                timing => 0,
  955.                search_path_on_include => 0,
  956.                cache => 0,               
  957.                blind_cache => 0,
  958.            file_cache => 0,
  959.            file_cache_dir => '',
  960.            file_cache_dir_mode => 0700,
  961.            force_untaint => 0,
  962.                cache_debug => 0,
  963.                shared_cache_debug => 0,
  964.                memory_debug => 0,
  965.                die_on_bad_params => 1,
  966.                vanguard_compatibility_mode => 0,
  967.                associate => [],
  968.                path => [],
  969.                strict => 1,
  970.                loop_context_vars => 0,
  971.                max_includes => 10,
  972.                shared_cache => 0,
  973.                double_cache => 0,
  974.                double_file_cache => 0,
  975.                ipc_key => 'TMPL',
  976.                ipc_mode => 0666,
  977.                ipc_segment_size => 65536,
  978.                ipc_max_size => 0,
  979.                global_vars => 0,
  980.                no_includes => 0,
  981.                case_sensitive => 0,
  982.                filter => [],
  983.               );
  984.   
  985.   # load in options supplied to new()
  986.   $options = _load_supplied_options( [@_], $options);
  987.  
  988.   # blind_cache = 1 implies cache = 1
  989.   $options->{blind_cache} and $options->{cache} = 1;
  990.  
  991.   # shared_cache = 1 implies cache = 1
  992.   $options->{shared_cache} and $options->{cache} = 1;
  993.  
  994.   # file_cache = 1 implies cache = 1
  995.   $options->{file_cache} and $options->{cache} = 1;
  996.  
  997.   # double_cache is a combination of shared_cache and cache.
  998.   $options->{double_cache} and $options->{cache} = 1;
  999.   $options->{double_cache} and $options->{shared_cache} = 1;
  1000.  
  1001.   # double_file_cache is a combination of file_cache and cache.
  1002.   $options->{double_file_cache} and $options->{cache} = 1;
  1003.   $options->{double_file_cache} and $options->{file_cache} = 1;
  1004.  
  1005.   # vanguard_compatibility_mode implies die_on_bad_params = 0
  1006.   $options->{vanguard_compatibility_mode} and 
  1007.     $options->{die_on_bad_params} = 0;
  1008.  
  1009.   # handle the "type", "source" parameter format (does anyone use it?)
  1010.   if (exists($options->{type})) {
  1011.     exists($options->{source}) or croak("HTML::Template->new() called with 'type' parameter set, but no 'source'!");
  1012.     ($options->{type} eq 'filename' or $options->{type} eq 'scalarref' or
  1013.      $options->{type} eq 'arrayref' or $options->{type} eq 'filehandle') or
  1014.        croak("HTML::Template->new() : type parameter must be set to 'filename', 'arrayref', 'scalarref' or 'filehandle'!");
  1015.  
  1016.     $options->{$options->{type}} = $options->{source};
  1017.     delete $options->{type};
  1018.     delete $options->{source};
  1019.   }
  1020.  
  1021.   # make sure taint mode is on if force_untaint flag is set
  1022.   if ($options->{force_untaint} && ! ${^TAINT}) {
  1023.     croak("HTML::Template->new() : 'force_untaint' option set but perl does not run in taint mode!");
  1024.   }
  1025.  
  1026.   # associate should be an array of one element if it's not
  1027.   # already an array.
  1028.   if (ref($options->{associate}) ne 'ARRAY') {
  1029.     $options->{associate} = [ $options->{associate} ];
  1030.   }
  1031.  
  1032.   # path should be an array if it's not already
  1033.   if (ref($options->{path}) ne 'ARRAY') {
  1034.     $options->{path} = [ $options->{path} ];
  1035.   }
  1036.  
  1037.   # filter should be an array if it's not already
  1038.   if (ref($options->{filter}) ne 'ARRAY') {
  1039.     $options->{filter} = [ $options->{filter} ];
  1040.   }
  1041.   
  1042.   # make sure objects in associate area support param()
  1043.   foreach my $object (@{$options->{associate}}) {
  1044.     defined($object->can('param')) or
  1045.       croak("HTML::Template->new called with associate option, containing object of type " . ref($object) . " which lacks a param() method!");
  1046.   } 
  1047.  
  1048.   # check for syntax errors:
  1049.   my $source_count = 0;
  1050.   exists($options->{filename}) and $source_count++;
  1051.   exists($options->{filehandle}) and $source_count++;
  1052.   exists($options->{arrayref}) and $source_count++;
  1053.   exists($options->{scalarref}) and $source_count++;
  1054.   if ($source_count != 1) {
  1055.     croak("HTML::Template->new called with multiple (or no) template sources specified!  A valid call to new() has exactly one filename => 'file' OR exactly one scalarref => \\\$scalar OR exactly one arrayref => \\\@array OR exactly one filehandle => \*FH");
  1056.   }
  1057.  
  1058.   # check that cache options are not used with non-cacheable templates
  1059.   croak "Cannot have caching when template source is not file"
  1060.     if grep { exists($options->{$_}) } qw( filehandle arrayref scalarref)
  1061.       and 
  1062.        grep {$options->{$_}} qw( cache blind_cache file_cache shared_cache 
  1063.                                  double_cache double_file_cache );
  1064.     
  1065.   # check that filenames aren't empty
  1066.   if (exists($options->{filename})) {
  1067.       croak("HTML::Template->new called with empty filename parameter!")
  1068.         unless length $options->{filename};
  1069.   }
  1070.  
  1071.   # do some memory debugging - this is best started as early as possible
  1072.   if ($options->{memory_debug}) {
  1073.     # memory_debug needs GTop
  1074.     eval { require GTop; };
  1075.     croak("Could not load GTop.  You must have GTop installed to use HTML::Template in memory_debug mode.  The error was: $@")
  1076.       if ($@);
  1077.     $self->{gtop} = GTop->new();
  1078.     $self->{proc_mem} = $self->{gtop}->proc_mem($$);
  1079.     print STDERR "\n### HTML::Template Memory Debug ### START ", $self->{proc_mem}->size(), "\n";
  1080.   }
  1081.  
  1082.   if ($options->{file_cache}) {
  1083.     # make sure we have a file_cache_dir option
  1084.     croak("You must specify the file_cache_dir option if you want to use file_cache.") 
  1085.       unless length $options->{file_cache_dir};
  1086.  
  1087.  
  1088.     # file_cache needs some extra modules loaded
  1089.     eval { require Storable; };
  1090.     croak("Could not load Storable.  You must have Storable installed to use HTML::Template in file_cache mode.  The error was: $@")
  1091.       if ($@);
  1092.   }
  1093.  
  1094.   if ($options->{shared_cache}) {
  1095.     # shared_cache needs some extra modules loaded
  1096.     eval { require IPC::SharedCache; };
  1097.     croak("Could not load IPC::SharedCache.  You must have IPC::SharedCache installed to use HTML::Template in shared_cache mode.  The error was: $@")
  1098.       if ($@);
  1099.  
  1100.     # initialize the shared cache
  1101.     my %cache;
  1102.     tie %cache, 'IPC::SharedCache',
  1103.       ipc_key => $options->{ipc_key},
  1104.       load_callback => [\&_load_shared_cache, $self],
  1105.       validate_callback => [\&_validate_shared_cache, $self],
  1106.       debug => $options->{shared_cache_debug},
  1107.       ipc_mode => $options->{ipc_mode},
  1108.       max_size => $options->{ipc_max_size},
  1109.       ipc_segment_size => $options->{ipc_segment_size};
  1110.     $self->{cache} = \%cache;
  1111.   }
  1112.  
  1113.   if ($options->{default_escape}) {
  1114.     $options->{default_escape} = uc $options->{default_escape};
  1115.     unless ($options->{default_escape} =~ /^(HTML|URL|JS)$/) {
  1116.       croak("HTML::Template->new(): Invalid setting for default_escape - '$options->{default_escape}'.  Valid values are HTML, URL or JS.");
  1117.     }
  1118.   }
  1119.  
  1120.   print STDERR "### HTML::Template Memory Debug ### POST CACHE INIT ", $self->{proc_mem}->size(), "\n"
  1121.     if $options->{memory_debug};
  1122.  
  1123.   # initialize data structures
  1124.   $self->_init;
  1125.   
  1126.   print STDERR "### HTML::Template Memory Debug ### POST _INIT CALL ", $self->{proc_mem}->size(), "\n"
  1127.     if $options->{memory_debug};
  1128.   
  1129.   # drop the shared cache - leaving out this step results in the
  1130.   # template object evading garbage collection since the callbacks in
  1131.   # the shared cache tie hold references to $self!  This was not easy
  1132.   # to find, by the way.
  1133.   delete $self->{cache} if $options->{shared_cache};
  1134.  
  1135.   return $self;
  1136. }
  1137.  
  1138. sub _load_supplied_options {
  1139.     my $argsref = shift;
  1140.     my $options = shift;
  1141.     for (my $x = 0; $x < @{$argsref}; $x += 2) {
  1142.       defined(${$argsref}[($x + 1)]) or croak(
  1143.         "HTML::Template->new() called with odd number of option parameters - should be of the form option => value");
  1144.       $options->{lc(${$argsref}[$x])} = ${$argsref}[($x + 1)]; 
  1145.     }
  1146.     return $options;
  1147. }
  1148.  
  1149. # an internally used new that receives its parse_stack and param_map as input
  1150. sub _new_from_loop {
  1151.   my $pkg = shift;
  1152.   my $self; { my %hash; $self = bless(\%hash, $pkg); }
  1153.  
  1154.   # the options hash
  1155.   my $options = {};
  1156.   $self->{options} = $options;
  1157.  
  1158.   # set default parameters in options hash - a subset of the options
  1159.   # valid in a normal new().  Since _new_from_loop never calls _init,
  1160.   # many options have no relevance.
  1161.   %$options = (
  1162.                debug => 0,
  1163.                stack_debug => 0,
  1164.                die_on_bad_params => 1,
  1165.                associate => [],
  1166.                loop_context_vars => 0,
  1167.               );
  1168.   
  1169.   # load in options supplied to new()
  1170.   $options = _load_supplied_options( [@_], $options);
  1171.  
  1172.   $self->{param_map} = $options->{param_map};
  1173.   $self->{parse_stack} = $options->{parse_stack};
  1174.   delete($options->{param_map});
  1175.   delete($options->{parse_stack});
  1176.  
  1177.   return $self;
  1178. }
  1179.  
  1180. # a few shortcuts to new(), of possible use...
  1181. sub new_file {
  1182.   my $pkg = shift; return $pkg->new('filename', @_);
  1183. }
  1184. sub new_filehandle {
  1185.   my $pkg = shift; return $pkg->new('filehandle', @_);
  1186. }
  1187. sub new_array_ref {
  1188.   my $pkg = shift; return $pkg->new('arrayref', @_);
  1189. }
  1190. sub new_scalar_ref {
  1191.   my $pkg = shift; return $pkg->new('scalarref', @_);
  1192. }
  1193.  
  1194. # initializes all the object data structures, either from cache or by
  1195. # calling the appropriate routines.
  1196. sub _init {
  1197.   my $self = shift;
  1198.   my $options = $self->{options};
  1199.  
  1200.   if ($options->{double_cache}) {
  1201.     # try the normal cache, return if we have it.
  1202.     $self->_fetch_from_cache();
  1203.     return if (defined $self->{param_map} and defined $self->{parse_stack});
  1204.  
  1205.     # try the shared cache
  1206.     $self->_fetch_from_shared_cache();
  1207.  
  1208.     # put it in the local cache if we got it.
  1209.     $self->_commit_to_cache()
  1210.       if (defined $self->{param_map} and defined $self->{parse_stack});
  1211.   } elsif ($options->{double_file_cache}) {
  1212.     # try the normal cache, return if we have it.
  1213.     $self->_fetch_from_cache();
  1214.     return if (defined $self->{param_map});
  1215.  
  1216.     # try the file cache
  1217.     $self->_fetch_from_file_cache();
  1218.  
  1219.     # put it in the local cache if we got it.
  1220.     $self->_commit_to_cache()
  1221.       if (defined $self->{param_map});
  1222.   } elsif ($options->{shared_cache}) {
  1223.     # try the shared cache
  1224.     $self->_fetch_from_shared_cache();
  1225.   } elsif ($options->{file_cache}) {
  1226.     # try the file cache
  1227.     $self->_fetch_from_file_cache();
  1228.   } elsif ($options->{cache}) {
  1229.     # try the normal cache
  1230.     $self->_fetch_from_cache();
  1231.   }
  1232.   
  1233.   # if we got a cache hit, return
  1234.   return if (defined $self->{param_map});
  1235.  
  1236.   # if we're here, then we didn't get a cached copy, so do a full
  1237.   # init.
  1238.   $self->_init_template();
  1239.   $self->_parse();
  1240.  
  1241.   # now that we have a full init, cache the structures if cacheing is
  1242.   # on.  shared cache is already cool.
  1243.   if($options->{file_cache}){
  1244.     $self->_commit_to_file_cache();
  1245.   }
  1246.   $self->_commit_to_cache() if (
  1247.          ($options->{cache} 
  1248.             and not $options->{shared_cache} 
  1249.             and not $options->{file_cache}
  1250.          ) 
  1251.       or ($options->{double_cache}) 
  1252.       or ($options->{double_file_cache})
  1253.     );
  1254. }
  1255.  
  1256. # Caching subroutines - they handle getting and validating cache
  1257. # records from either the in-memory or shared caches.
  1258.  
  1259. # handles the normal in memory cache
  1260. use vars qw( %CACHE );
  1261. sub _fetch_from_cache {
  1262.   my $self = shift;
  1263.   my $options = $self->{options};
  1264.  
  1265.   # return if there's no file here
  1266.   my $filepath = $self->_find_file($options->{filename});
  1267.   return unless (defined($filepath));
  1268.   $options->{filepath} = $filepath;
  1269.  
  1270.   # return if there's no cache entry for this key
  1271.   my $key = $self->_cache_key();
  1272.   return unless exists($CACHE{$key});  
  1273.   
  1274.   # validate the cache
  1275.   my $mtime = $self->_mtime($filepath);  
  1276.   if (defined $mtime) {
  1277.     # return if the mtime doesn't match the cache
  1278.     if (defined($CACHE{$key}{mtime}) and 
  1279.         ($mtime != $CACHE{$key}{mtime})) {
  1280.       $options->{cache_debug} and 
  1281.         print STDERR "CACHE MISS : $filepath : $mtime\n";
  1282.       return;
  1283.     }
  1284.  
  1285.     # if the template has includes, check each included file's mtime
  1286.     # and return if different
  1287.     if (exists($CACHE{$key}{included_mtimes})) {
  1288.       foreach my $filename (keys %{$CACHE{$key}{included_mtimes}}) {
  1289.         next unless 
  1290.           defined($CACHE{$key}{included_mtimes}{$filename});
  1291.         
  1292.         my $included_mtime = (stat($filename))[9];
  1293.         if ($included_mtime != $CACHE{$key}{included_mtimes}{$filename}) {
  1294.           $options->{cache_debug} and 
  1295.             print STDERR "### HTML::Template Cache Debug ### CACHE MISS : $filepath : INCLUDE $filename : $included_mtime\n";
  1296.           
  1297.           return;
  1298.         }
  1299.       }
  1300.     }
  1301.   }
  1302.  
  1303.   # got a cache hit!
  1304.   
  1305.   $options->{cache_debug} and print STDERR "### HTML::Template Cache Debug ### CACHE HIT : $filepath => $key\n";
  1306.       
  1307.   $self->{param_map} = $CACHE{$key}{param_map};
  1308.   $self->{parse_stack} = $CACHE{$key}{parse_stack};
  1309.   exists($CACHE{$key}{included_mtimes}) and
  1310.     $self->{included_mtimes} = $CACHE{$key}{included_mtimes};
  1311.  
  1312.   # clear out values from param_map from last run
  1313.   $self->_normalize_options();
  1314.   $self->clear_params();
  1315. }
  1316.  
  1317. sub _commit_to_cache {
  1318.   my $self     = shift;
  1319.   my $options  = $self->{options};
  1320.   my $key      = $self->_cache_key();
  1321.   my $filepath = $options->{filepath};
  1322.  
  1323.   $options->{cache_debug} and print STDERR "### HTML::Template Cache Debug ### CACHE LOAD : $filepath => $key\n";
  1324.     
  1325.   $options->{blind_cache} or
  1326.     $CACHE{$key}{mtime} = $self->_mtime($filepath);
  1327.   $CACHE{$key}{param_map} = $self->{param_map};
  1328.   $CACHE{$key}{parse_stack} = $self->{parse_stack};
  1329.   exists($self->{included_mtimes}) and
  1330.     $CACHE{$key}{included_mtimes} = $self->{included_mtimes};
  1331. }
  1332.  
  1333. # create a cache key from a template object.  The cache key includes
  1334. # the full path to the template and options which affect template
  1335. # loading.  Has the side-effect of loading $self->{options}{filepath}
  1336. sub _cache_key {
  1337.     my $self = shift;
  1338.     my $options = $self->{options};
  1339.  
  1340.     # assemble pieces of the key
  1341.     my @key = ($options->{filepath});
  1342.     push(@key, @{$options->{path}});
  1343.     push(@key, $options->{search_path_on_include} || 0);
  1344.     push(@key, $options->{loop_context_vars} || 0);
  1345.     push(@key, $options->{global_vars} || 0);
  1346.  
  1347.     # compute the md5 and return it
  1348.     return md5_hex(@key);
  1349. }
  1350.  
  1351. # generates MD5 from filepath to determine filename for cache file
  1352. sub _get_cache_filename {
  1353.   my ($self, $filepath) = @_;
  1354.  
  1355.   # get a cache key
  1356.   $self->{options}{filepath} = $filepath;
  1357.   my $hash = $self->_cache_key();
  1358.   
  1359.   # ... and build a path out of it.  Using the first two charcters
  1360.   # gives us 255 buckets.  This means you can have 255,000 templates
  1361.   # in the cache before any one directory gets over a few thousand
  1362.   # files in it.  That's probably pretty good for this planet.  If not
  1363.   # then it should be configurable.
  1364.   if (wantarray) {
  1365.     return (substr($hash,0,2), substr($hash,2))
  1366.   } else {
  1367.     return File::Spec->join($self->{options}{file_cache_dir}, 
  1368.                             substr($hash,0,2), substr($hash,2));
  1369.   }
  1370. }
  1371.  
  1372. # handles the file cache
  1373. sub _fetch_from_file_cache {
  1374.   my $self = shift;
  1375.   my $options = $self->{options};
  1376.   
  1377.   # return if there's no cache entry for this filename
  1378.   my $filepath = $self->_find_file($options->{filename});
  1379.   return unless defined $filepath;
  1380.   my $cache_filename = $self->_get_cache_filename($filepath);
  1381.   return unless -e $cache_filename;
  1382.   
  1383.   eval {
  1384.     $self->{record} = Storable::lock_retrieve($cache_filename);
  1385.   };
  1386.   croak("HTML::Template::new() - Problem reading cache file $cache_filename (file_cache => 1) : $@")
  1387.     if $@;
  1388.   croak("HTML::Template::new() - Problem reading cache file $cache_filename (file_cache => 1) : $!") 
  1389.     unless defined $self->{record};
  1390.  
  1391.   ($self->{mtime}, 
  1392.    $self->{included_mtimes}, 
  1393.    $self->{param_map}, 
  1394.    $self->{parse_stack}) = @{$self->{record}};
  1395.   
  1396.   $options->{filepath} = $filepath;
  1397.  
  1398.   # validate the cache
  1399.   my $mtime = $self->_mtime($filepath);
  1400.   if (defined $mtime) {
  1401.     # return if the mtime doesn't match the cache
  1402.     if (defined($self->{mtime}) and 
  1403.         ($mtime != $self->{mtime})) {
  1404.       $options->{cache_debug} and 
  1405.         print STDERR "### HTML::Template Cache Debug ### FILE CACHE MISS : $filepath : $mtime\n";
  1406.       ($self->{mtime}, 
  1407.        $self->{included_mtimes}, 
  1408.        $self->{param_map}, 
  1409.        $self->{parse_stack}) = (undef, undef, undef, undef);
  1410.       return;
  1411.     }
  1412.  
  1413.     # if the template has includes, check each included file's mtime
  1414.     # and return if different
  1415.     if (exists($self->{included_mtimes})) {
  1416.       foreach my $filename (keys %{$self->{included_mtimes}}) {
  1417.         next unless 
  1418.           defined($self->{included_mtimes}{$filename});
  1419.         
  1420.         my $included_mtime = (stat($filename))[9];
  1421.         if ($included_mtime != $self->{included_mtimes}{$filename}) {
  1422.           $options->{cache_debug} and 
  1423.             print STDERR "### HTML::Template Cache Debug ### FILE CACHE MISS : $filepath : INCLUDE $filename : $included_mtime\n";
  1424.           ($self->{mtime}, 
  1425.            $self->{included_mtimes}, 
  1426.            $self->{param_map}, 
  1427.            $self->{parse_stack}) = (undef, undef, undef, undef);
  1428.           return;
  1429.         }
  1430.       }
  1431.     }
  1432.   }
  1433.  
  1434.   # got a cache hit!
  1435.   $options->{cache_debug} and print STDERR "### HTML::Template Cache Debug ### FILE CACHE HIT : $filepath\n";
  1436.  
  1437.   # clear out values from param_map from last run
  1438.   $self->_normalize_options();
  1439.   $self->clear_params();
  1440. }
  1441.  
  1442. sub _commit_to_file_cache {
  1443.   my $self = shift;
  1444.   my $options = $self->{options};
  1445.  
  1446.   my $filepath = $options->{filepath};
  1447.   if (not defined $filepath) {
  1448.     $filepath = $self->_find_file($options->{filename});
  1449.     confess("HTML::Template->new() : Cannot open included file $options->{filename} : file not found.")
  1450.       unless defined($filepath);
  1451.     $options->{filepath} = $filepath;   
  1452.   }
  1453.  
  1454.   my ($cache_dir, $cache_file) = $self->_get_cache_filename($filepath);  
  1455.   $cache_dir = File::Spec->join($options->{file_cache_dir}, $cache_dir);
  1456.   if (not -d $cache_dir) {
  1457.     if (not -d $options->{file_cache_dir}) {
  1458.       mkdir($options->{file_cache_dir},$options->{file_cache_dir_mode})
  1459.     or croak("HTML::Template->new() : can't mkdir $options->{file_cache_dir} (file_cache => 1): $!");
  1460.     }
  1461.     mkdir($cache_dir,$options->{file_cache_dir_mode})
  1462.       or croak("HTML::Template->new() : can't mkdir $cache_dir (file_cache => 1): $!");
  1463.   }
  1464.  
  1465.   $options->{cache_debug} and print STDERR "### HTML::Template Cache Debug ### FILE CACHE LOAD : $options->{filepath}\n";
  1466.  
  1467.   my $result;
  1468.   eval {
  1469.     $result = Storable::lock_store([ $self->{mtime},
  1470.                                      $self->{included_mtimes}, 
  1471.                                      $self->{param_map}, 
  1472.                                      $self->{parse_stack} ],
  1473.                                    scalar File::Spec->join($cache_dir, $cache_file)
  1474.                                   );
  1475.   };
  1476.   croak("HTML::Template::new() - Problem writing cache file $cache_dir/$cache_file (file_cache => 1) : $@")
  1477.     if $@;
  1478.   croak("HTML::Template::new() - Problem writing cache file $cache_dir/$cache_file (file_cache => 1) : $!")
  1479.     unless defined $result;
  1480. }
  1481.  
  1482. # Shared cache routines.
  1483. sub _fetch_from_shared_cache {
  1484.   my $self = shift;
  1485.   my $options = $self->{options};
  1486.  
  1487.   my $filepath = $self->_find_file($options->{filename});
  1488.   return unless defined $filepath;
  1489.  
  1490.   # fetch from the shared cache.
  1491.   $self->{record} = $self->{cache}{$filepath};
  1492.   
  1493.   ($self->{mtime}, 
  1494.    $self->{included_mtimes}, 
  1495.    $self->{param_map}, 
  1496.    $self->{parse_stack}) = @{$self->{record}}
  1497.      if defined($self->{record});
  1498.   
  1499.   $options->{cache_debug} and defined($self->{record}) and print STDERR "### HTML::Template Cache Debug ### CACHE HIT : $filepath\n";
  1500.   # clear out values from param_map from last run
  1501.   $self->_normalize_options(), $self->clear_params()
  1502.     if (defined($self->{record}));
  1503.   delete($self->{record});
  1504.  
  1505.   return $self;
  1506. }
  1507.  
  1508. sub _validate_shared_cache {
  1509.   my ($self, $filename, $record) = @_;
  1510.   my $options = $self->{options};
  1511.  
  1512.   $options->{shared_cache_debug} and print STDERR "### HTML::Template Cache Debug ### SHARED CACHE VALIDATE : $filename\n";
  1513.  
  1514.   return 1 if $options->{blind_cache};
  1515.  
  1516.   my ($c_mtime, $included_mtimes, $param_map, $parse_stack) = @$record;
  1517.  
  1518.   # if the modification time has changed return false
  1519.   my $mtime = $self->_mtime($filename);
  1520.   if (defined $mtime and defined $c_mtime
  1521.       and $mtime != $c_mtime) {
  1522.     $options->{cache_debug} and 
  1523.       print STDERR "### HTML::Template Cache Debug ### SHARED CACHE MISS : $filename : $mtime\n";
  1524.     return 0;
  1525.   }
  1526.  
  1527.   # if the template has includes, check each included file's mtime
  1528.   # and return false if different
  1529.   if (defined $mtime and defined $included_mtimes) {
  1530.     foreach my $fname (keys %$included_mtimes) {
  1531.       next unless defined($included_mtimes->{$fname});
  1532.       if ($included_mtimes->{$fname} != (stat($fname))[9]) {
  1533.         $options->{cache_debug} and 
  1534.           print STDERR "### HTML::Template Cache Debug ### SHARED CACHE MISS : $filename : INCLUDE $fname\n";
  1535.         return 0;
  1536.       }
  1537.     }
  1538.   }
  1539.  
  1540.   # all done - return true
  1541.   return 1;
  1542. }
  1543.  
  1544. sub _load_shared_cache {
  1545.   my ($self, $filename) = @_;
  1546.   my $options = $self->{options};
  1547.   my $cache = $self->{cache};
  1548.   
  1549.   $self->_init_template();
  1550.   $self->_parse();
  1551.  
  1552.   $options->{cache_debug} and print STDERR "### HTML::Template Cache Debug ### SHARED CACHE LOAD : $options->{filepath}\n";
  1553.   
  1554.   print STDERR "### HTML::Template Memory Debug ### END CACHE LOAD ", $self->{proc_mem}->size(), "\n"
  1555.     if $options->{memory_debug};
  1556.  
  1557.   return [ $self->{mtime},
  1558.            $self->{included_mtimes}, 
  1559.            $self->{param_map}, 
  1560.            $self->{parse_stack} ]; 
  1561. }
  1562.  
  1563. # utility function - given a filename performs documented search and
  1564. # returns a full path or undef if the file cannot be found.
  1565. sub _find_file {
  1566.   my ($self, $filename, $extra_path) = @_;
  1567.   my $options = $self->{options};
  1568.   my $filepath;
  1569.  
  1570.   # first check for a full path
  1571.   return File::Spec->canonpath($filename)
  1572.     if (File::Spec->file_name_is_absolute($filename) and (-e $filename));
  1573.  
  1574.   # try the extra_path if one was specified
  1575.   if (defined($extra_path)) {
  1576.     $extra_path->[$#{$extra_path}] = $filename;
  1577.     $filepath = File::Spec->canonpath(File::Spec->catfile(@$extra_path));
  1578.     return File::Spec->canonpath($filepath) if -e $filepath;
  1579.   }
  1580.  
  1581.   # try pre-prending HTML_Template_Root
  1582.   if (defined($ENV{HTML_TEMPLATE_ROOT})) {
  1583.     $filepath =  File::Spec->catfile($ENV{HTML_TEMPLATE_ROOT}, $filename);
  1584.     return File::Spec->canonpath($filepath) if -e $filepath;
  1585.   }
  1586.  
  1587.   # try "path" option list..
  1588.   foreach my $path (@{$options->{path}}) {
  1589.     $filepath = File::Spec->catfile($path, $filename);
  1590.     return File::Spec->canonpath($filepath) if -e $filepath;
  1591.   }
  1592.  
  1593.   # try even a relative path from the current directory...
  1594.   return File::Spec->canonpath($filename) if -e $filename;
  1595.  
  1596.   # try "path" option list with HTML_TEMPLATE_ROOT prepended...
  1597.   if (defined($ENV{HTML_TEMPLATE_ROOT})) {
  1598.     foreach my $path (@{$options->{path}}) {
  1599.       $filepath = File::Spec->catfile($ENV{HTML_TEMPLATE_ROOT}, $path, $filename);
  1600.       return File::Spec->canonpath($filepath) if -e $filepath;
  1601.     }
  1602.   }
  1603.   
  1604.   return undef;
  1605. }
  1606.  
  1607. # utility function - computes the mtime for $filename
  1608. sub _mtime {
  1609.   my ($self, $filepath) = @_;
  1610.   my $options = $self->{options};
  1611.   
  1612.   return(undef) if ($options->{blind_cache});
  1613.  
  1614.   # make sure it still exists in the filesystem 
  1615.   (-r $filepath) or Carp::confess("HTML::Template : template file $filepath does not exist or is unreadable.");
  1616.   
  1617.   # get the modification time
  1618.   return (stat(_))[9];
  1619. }
  1620.  
  1621. # utility function - enforces new() options across LOOPs that have
  1622. # come from a cache.  Otherwise they would have stale options hashes.
  1623. sub _normalize_options {
  1624.   my $self = shift;
  1625.   my $options = $self->{options};
  1626.  
  1627.   my @pstacks = ($self->{parse_stack});
  1628.   while(@pstacks) {
  1629.     my $pstack = pop(@pstacks);
  1630.     foreach my $item (@$pstack) {
  1631.       next unless (ref($item) eq 'HTML::Template::LOOP');
  1632.       foreach my $template (values %{$item->[HTML::Template::LOOP::TEMPLATE_HASH]}) {
  1633.         # must be the same list as the call to _new_from_loop...
  1634.         $template->{options}{debug} = $options->{debug};
  1635.         $template->{options}{stack_debug} = $options->{stack_debug};
  1636.         $template->{options}{die_on_bad_params} = $options->{die_on_bad_params};
  1637.         $template->{options}{case_sensitive} = $options->{case_sensitive};
  1638.         $template->{options}{parent_global_vars} = $options->{parent_global_vars};
  1639.  
  1640.         push(@pstacks, $template->{parse_stack});
  1641.       }
  1642.     }
  1643.   }
  1644. }      
  1645.  
  1646. # initialize the template buffer
  1647. sub _init_template {
  1648.   my $self = shift;
  1649.   my $options = $self->{options};
  1650.  
  1651.   print STDERR "### HTML::Template Memory Debug ### START INIT_TEMPLATE ", $self->{proc_mem}->size(), "\n"
  1652.     if $options->{memory_debug};
  1653.  
  1654.   if (exists($options->{filename})) {    
  1655.     my $filepath = $options->{filepath};
  1656.     if (not defined $filepath) {
  1657.       $filepath = $self->_find_file($options->{filename});
  1658.       confess("HTML::Template->new() : Cannot open included file $options->{filename} : file not found.")
  1659.         unless defined($filepath);
  1660.       # we'll need this for future reference - to call stat() for example.
  1661.       $options->{filepath} = $filepath;   
  1662.     }
  1663.  
  1664.     confess("HTML::Template->new() : Cannot open included file $options->{filename} : $!")
  1665.         unless defined(open(TEMPLATE, $filepath));
  1666.     $self->{mtime} = $self->_mtime($filepath);
  1667.  
  1668.     # read into scalar, note the mtime for the record
  1669.     $self->{template} = "";
  1670.     while (read(TEMPLATE, $self->{template}, 10240, length($self->{template}))) {}
  1671.     close(TEMPLATE);
  1672.  
  1673.   } elsif (exists($options->{scalarref})) {
  1674.     # copy in the template text
  1675.     $self->{template} = ${$options->{scalarref}};
  1676.  
  1677.     delete($options->{scalarref});
  1678.   } elsif (exists($options->{arrayref})) {
  1679.     # if we have an array ref, join and store the template text
  1680.     $self->{template} = join("", @{$options->{arrayref}});
  1681.  
  1682.     delete($options->{arrayref});
  1683.   } elsif (exists($options->{filehandle})) {
  1684.     # just read everything in in one go
  1685.     local $/ = undef;
  1686.     $self->{template} = readline($options->{filehandle});
  1687.  
  1688.     delete($options->{filehandle});
  1689.   } else {
  1690.     confess("HTML::Template : Need to call new with filename, filehandle, scalarref or arrayref parameter specified.");
  1691.   }
  1692.  
  1693.   print STDERR "### HTML::Template Memory Debug ### END INIT_TEMPLATE ", $self->{proc_mem}->size(), "\n"
  1694.     if $options->{memory_debug};
  1695.  
  1696.   # handle filters if necessary
  1697.   $self->_call_filters(\$self->{template}) if @{$options->{filter}};
  1698.  
  1699.   return $self;
  1700. }
  1701.  
  1702. # handle calling user defined filters
  1703. sub _call_filters {
  1704.   my $self = shift;
  1705.   my $template_ref = shift;
  1706.   my $options = $self->{options};
  1707.  
  1708.   my ($format, $sub);
  1709.   foreach my $filter (@{$options->{filter}}) {
  1710.     croak("HTML::Template->new() : bad value set for filter parameter - must be a code ref or a hash ref.")
  1711.       unless ref $filter;
  1712.  
  1713.     # translate into CODE->HASH
  1714.     $filter = { 'format' => 'scalar', 'sub' => $filter }
  1715.       if (ref $filter eq 'CODE');
  1716.  
  1717.     if (ref $filter eq 'HASH') {
  1718.       $format = $filter->{'format'};
  1719.       $sub = $filter->{'sub'};
  1720.  
  1721.       # check types and values
  1722.       croak("HTML::Template->new() : bad value set for filter parameter - hash must contain \"format\" key and \"sub\" key.")
  1723.         unless defined $format and defined $sub;
  1724.       croak("HTML::Template->new() : bad value set for filter parameter - \"format\" must be either 'array' or 'scalar'")
  1725.         unless $format eq 'array' or $format eq 'scalar';
  1726.       croak("HTML::Template->new() : bad value set for filter parameter - \"sub\" must be a code ref")
  1727.         unless ref $sub and ref $sub eq 'CODE';
  1728.  
  1729.       # catch errors
  1730.       eval {
  1731.         if ($format eq 'scalar') {
  1732.           # call
  1733.           $sub->($template_ref);
  1734.         } else {
  1735.       # modulate
  1736.       my @array = map { $_."\n" } split("\n", $$template_ref);
  1737.           # call
  1738.           $sub->(\@array);
  1739.       # demodulate
  1740.       $$template_ref = join("", @array);
  1741.         }
  1742.       };
  1743.       croak("HTML::Template->new() : fatal error occured during filter call: $@") if $@;
  1744.     } else {
  1745.       croak("HTML::Template->new() : bad value set for filter parameter - must be code ref or hash ref");
  1746.     }
  1747.   }
  1748.   # all done
  1749.   return $template_ref;
  1750. }
  1751.  
  1752. # _parse sifts through a template building up the param_map and
  1753. # parse_stack structures.
  1754. #
  1755. # The end result is a Template object that is fully ready for
  1756. # output().
  1757. sub _parse {
  1758.   my $self = shift;
  1759.   my $options = $self->{options};
  1760.   
  1761.   $options->{debug} and print STDERR "### HTML::Template Debug ### In _parse:\n";
  1762.   
  1763.   # setup the stacks and maps - they're accessed by typeglobs that
  1764.   # reference the top of the stack.  They are masked so that a loop
  1765.   # can transparently have its own versions.
  1766.   use vars qw(@pstack %pmap @ifstack @ucstack %top_pmap);
  1767.   local (*pstack, *ifstack, *pmap, *ucstack, *top_pmap);
  1768.   
  1769.   # the pstack is the array of scalar refs (plain text from the
  1770.   # template file), VARs, LOOPs, IFs and ELSEs that output() works on
  1771.   # to produce output.  Looking at output() should make it clear what
  1772.   # _parse is trying to accomplish.
  1773.   my @pstacks = ([]);
  1774.   *pstack = $pstacks[0];
  1775.   $self->{parse_stack} = $pstacks[0];
  1776.   
  1777.   # the pmap binds names to VARs, LOOPs and IFs.  It allows param() to
  1778.   # access the right variable.  NOTE: output() does not look at the
  1779.   # pmap at all!
  1780.   my @pmaps = ({});
  1781.   *pmap = $pmaps[0];
  1782.   *top_pmap = $pmaps[0];
  1783.   $self->{param_map} = $pmaps[0];
  1784.  
  1785.   # the ifstack is a temporary stack containing pending ifs and elses
  1786.   # waiting for a /if.
  1787.   my @ifstacks = ([]);
  1788.   *ifstack = $ifstacks[0];
  1789.  
  1790.   # the ucstack is a temporary stack containing conditions that need
  1791.   # to be bound to param_map entries when their block is finished.
  1792.   # This happens when a conditional is encountered before any other
  1793.   # reference to its NAME.  Since a conditional can reference VARs and
  1794.   # LOOPs it isn't possible to make the link right away.
  1795.   my @ucstacks = ([]);
  1796.   *ucstack = $ucstacks[0];
  1797.   
  1798.   # the loopstack is another temp stack for closing loops.  unlike
  1799.   # those above it doesn't get scoped inside loops, therefore it
  1800.   # doesn't need the typeglob magic.
  1801.   my @loopstack = ();
  1802.  
  1803.   # the fstack is a stack of filenames and counters that keeps track
  1804.   # of which file we're in and where we are in it.  This allows
  1805.   # accurate error messages even inside included files!
  1806.   # fcounter, fmax and fname are aliases for the current file's info
  1807.   use vars qw($fcounter $fname $fmax);
  1808.   local (*fcounter, *fname, *fmax);
  1809.  
  1810.   my @fstack = ([$options->{filepath} || "/fake/path/for/non/file/template",
  1811.                  1, 
  1812.                  scalar @{[$self->{template} =~ m/(\n)/g]} + 1
  1813.                 ]);
  1814.   (*fname, *fcounter, *fmax) = \ ( @{$fstack[0]} );
  1815.  
  1816.   my $NOOP = HTML::Template::NOOP->new();
  1817.   my $ESCAPE = HTML::Template::ESCAPE->new();
  1818.   my $JSESCAPE = HTML::Template::JSESCAPE->new();
  1819.   my $URLESCAPE = HTML::Template::URLESCAPE->new();
  1820.  
  1821.   # all the tags that need NAMEs:
  1822.   my %need_names = map { $_ => 1 } 
  1823.     qw(TMPL_VAR TMPL_LOOP TMPL_IF TMPL_UNLESS TMPL_INCLUDE);
  1824.     
  1825.   # variables used below that don't need to be my'd in the loop
  1826.   my ($name, $which, $escape, $default);
  1827.  
  1828.   # handle the old vanguard format
  1829.   $options->{vanguard_compatibility_mode} and 
  1830.     $self->{template} =~ s/%([-\w\/\.+]+)%/<TMPL_VAR NAME=$1>/g;
  1831.  
  1832.   # now split up template on '<', leaving them in
  1833.   my @chunks = split(m/(?=<)/, $self->{template});
  1834.  
  1835.   # all done with template
  1836.   delete $self->{template};
  1837.  
  1838.   # loop through chunks, filling up pstack
  1839.   my $last_chunk =  $#chunks;
  1840.  CHUNK: for (my $chunk_number = 0;
  1841.         $chunk_number <= $last_chunk;
  1842.         $chunk_number++) {
  1843.     next unless defined $chunks[$chunk_number]; 
  1844.     my $chunk = $chunks[$chunk_number];
  1845.     
  1846.     # a general regex to match any and all TMPL_* tags 
  1847.     if ($chunk =~ /^<
  1848.                     (?:!--\s*)?
  1849.                     (
  1850.                       \/?[Tt][Mm][Pp][Ll]_
  1851.                       (?:
  1852.                          (?:[Vv][Aa][Rr])
  1853.                          |
  1854.                          (?:[Ll][Oo][Oo][Pp])
  1855.                          |
  1856.                          (?:[Ii][Ff])
  1857.                          |
  1858.                          (?:[Ee][Ll][Ss][Ee])
  1859.                          |
  1860.                          (?:[Uu][Nn][Ll][Ee][Ss][Ss])
  1861.                          |
  1862.                          (?:[Ii][Nn][Cc][Ll][Uu][Dd][Ee])
  1863.                       )
  1864.                     ) # $1 => $which - start of the tag
  1865.  
  1866.                     \s* 
  1867.  
  1868.                     # DEFAULT attribute
  1869.                     (?:
  1870.                       [Dd][Ee][Ff][Aa][Uu][Ll][Tt]
  1871.                       \s*=\s*
  1872.                       (?:
  1873.                         "([^">]*)"  # $2 => double-quoted DEFAULT value "
  1874.                         |
  1875.                         '([^'>]*)'  # $3 => single-quoted DEFAULT value
  1876.                         |
  1877.                         ([^\s=>]*)  # $4 => unquoted DEFAULT value
  1878.                       )
  1879.                     )?
  1880.  
  1881.                     \s*
  1882.  
  1883.                     # ESCAPE attribute
  1884.                     (?:
  1885.                       [Ee][Ss][Cc][Aa][Pp][Ee]
  1886.                       \s*=\s*
  1887.                       (?:
  1888.                         (
  1889.                            (?:["']?0["']?)|
  1890.                            (?:["']?1["']?)|
  1891.                            (?:["']?[Hh][Tt][Mm][Ll]["']?) |
  1892.                            (?:["']?[Uu][Rr][Ll]["']?) |
  1893.                            (?:["']?[Jj][Ss]["']?) |
  1894.                            (?:["']?[Nn][Oo][Nn][Ee]["']?)
  1895.                          )                         # $5 => ESCAPE on
  1896.                        )
  1897.                     )* # allow multiple ESCAPEs
  1898.  
  1899.                     \s*
  1900.  
  1901.                     # DEFAULT attribute
  1902.                     (?:
  1903.                       [Dd][Ee][Ff][Aa][Uu][Ll][Tt]
  1904.                       \s*=\s*
  1905.                       (?:
  1906.                         "([^">]*)"  # $6 => double-quoted DEFAULT value "
  1907.                         |
  1908.                         '([^'>]*)'  # $7 => single-quoted DEFAULT value
  1909.                         |
  1910.                         ([^\s=>]*)  # $8 => unquoted DEFAULT value
  1911.                       )
  1912.                     )?
  1913.  
  1914.                     \s*                    
  1915.  
  1916.                     # NAME attribute
  1917.                     (?:
  1918.                       (?:
  1919.                         [Nn][Aa][Mm][Ee]
  1920.                         \s*=\s*
  1921.                       )?
  1922.                       (?:
  1923.                         "([^">]*)"  # $9 => double-quoted NAME value "
  1924.                         |
  1925.                         '([^'>]*)'  # $10 => single-quoted NAME value
  1926.                         |
  1927.                         ([^\s=>]*)  # $11 => unquoted NAME value
  1928.                       )
  1929.                     )? 
  1930.                     
  1931.                     \s*
  1932.  
  1933.                     # DEFAULT attribute
  1934.                     (?:
  1935.                       [Dd][Ee][Ff][Aa][Uu][Ll][Tt]
  1936.                       \s*=\s*
  1937.                       (?:
  1938.                         "([^">]*)"  # $12 => double-quoted DEFAULT value "
  1939.                         |
  1940.                         '([^'>]*)'  # $13 => single-quoted DEFAULT value
  1941.                         |
  1942.                         ([^\s=>]*)  # $14 => unquoted DEFAULT value
  1943.                       )
  1944.                     )?
  1945.  
  1946.                     \s*
  1947.  
  1948.                     # ESCAPE attribute
  1949.                     (?:
  1950.                       [Ee][Ss][Cc][Aa][Pp][Ee]
  1951.                       \s*=\s*
  1952.                       (?:
  1953.                         (
  1954.                            (?:["']?0["']?)|
  1955.                            (?:["']?1["']?)|
  1956.                            (?:["']?[Hh][Tt][Mm][Ll]["']?) |
  1957.                            (?:["']?[Uu][Rr][Ll]["']?) |
  1958.                            (?:["']?[Jj][Ss]["']?) |
  1959.                            (?:["']?[Nn][Oo][Nn][Ee]["']?)
  1960.                          )                         # $15 => ESCAPE on
  1961.                        )
  1962.                     )* # allow multiple ESCAPEs
  1963.  
  1964.                     \s*
  1965.  
  1966.                     # DEFAULT attribute
  1967.                     (?:
  1968.                       [Dd][Ee][Ff][Aa][Uu][Ll][Tt]
  1969.                       \s*=\s*
  1970.                       (?:
  1971.                         "([^">]*)"  # $16 => double-quoted DEFAULT value "
  1972.                         |
  1973.                         '([^'>]*)'  # $17 => single-quoted DEFAULT value
  1974.                         |
  1975.                         ([^\s=>]*)  # $18 => unquoted DEFAULT value
  1976.                       )
  1977.                     )?
  1978.  
  1979.                     \s*
  1980.  
  1981.                     (?:--)?>                    
  1982.                     (.*) # $19 => $post - text that comes after the tag
  1983.                    $/sx) {
  1984.  
  1985.       $which = uc($1); # which tag is it
  1986.  
  1987.       $escape = defined $5 ? $5 : defined $15 ? $15
  1988.         : (defined $options->{default_escape} && $which eq 'TMPL_VAR') ? $options->{default_escape} : 0; # escape set?
  1989.       
  1990.       # what name for the tag?  undef for a /tag at most, one of the
  1991.       # following three will be defined
  1992.       $name = defined $9 ? $9 : defined $10 ? $10 : defined $11 ? $11 : undef;
  1993.  
  1994.       # is there a default?
  1995.       $default = defined $2  ? $2  : defined $3  ? $3  : defined $4  ? $4 : 
  1996.                  defined $6  ? $6  : defined $7  ? $7  : defined $8  ? $8 : 
  1997.                  defined $12 ? $12 : defined $13 ? $13 : defined $14 ? $14 : 
  1998.                  defined $16 ? $16 : defined $17 ? $17 : defined $18 ? $18 :
  1999.                  undef;
  2000.  
  2001.       my $post = $19; # what comes after on the line
  2002.  
  2003.       # allow mixed case in filenames, otherwise flatten
  2004.       $name = lc($name) unless (not defined $name or $which eq 'TMPL_INCLUDE' or $options->{case_sensitive});
  2005.  
  2006.       # die if we need a name and didn't get one
  2007.       die "HTML::Template->new() : No NAME given to a $which tag at $fname : line $fcounter." 
  2008.         if ($need_names{$which} and (not defined $name or not length $name));
  2009.  
  2010.       # die if we got an escape but can't use one
  2011.       die "HTML::Template->new() : ESCAPE option invalid in a $which tag at $fname : line $fcounter." if ( $escape and ($which ne 'TMPL_VAR'));
  2012.  
  2013.       # die if we got a default but can't use one
  2014.       die "HTML::Template->new() : DEFAULT option invalid in a $which tag at $fname : line $fcounter." if ( defined $default and ($which ne 'TMPL_VAR'));
  2015.         
  2016.       # take actions depending on which tag found
  2017.       if ($which eq 'TMPL_VAR') {
  2018.     $options->{debug} and print STDERR "### HTML::Template Debug ### $fname : line $fcounter : parsed VAR $name\n";
  2019.     
  2020.     # if we already have this var, then simply link to the existing
  2021.     # HTML::Template::VAR, else create a new one.        
  2022.     my $var;        
  2023.     if (exists $pmap{$name}) {
  2024.       $var = $pmap{$name};
  2025.       (ref($var) eq 'HTML::Template::VAR') or
  2026.         die "HTML::Template->new() : Already used param name $name as a TMPL_LOOP, found in a TMPL_VAR at $fname : line $fcounter.";
  2027.     } else {
  2028.       $var = HTML::Template::VAR->new();
  2029.       $pmap{$name} = $var;
  2030.       $top_pmap{$name} = HTML::Template::VAR->new()
  2031.         if $options->{global_vars} and not exists $top_pmap{$name};
  2032.     }
  2033.  
  2034.         # if a DEFAULT was provided, push a DEFAULT object on the
  2035.         # stack before the variable.
  2036.     if (defined $default) {
  2037.             push(@pstack, HTML::Template::DEFAULT->new($default));
  2038.         }
  2039.     
  2040.     # if ESCAPE was set, push an ESCAPE op on the stack before
  2041.     # the variable.  output will handle the actual work.
  2042.         # unless of course, they have set escape=0 or escape=none
  2043.     if ($escape) {
  2044.           if ($escape =~ /^["']?[Uu][Rr][Ll]["']?$/) {
  2045.             push(@pstack, $URLESCAPE);
  2046.           } elsif ($escape =~ /^["']?[Jj][Ss]["']?$/) {
  2047.         push(@pstack, $JSESCAPE);
  2048.           } elsif ($escape =~ /^["']?0["']?$/) {
  2049.             # do nothing if escape=0
  2050.           } elsif ($escape =~ /^["']?[Nn][Oo][Nn][Ee]["']?$/ ) {
  2051.             # do nothing if escape=none
  2052.           } else {
  2053.         push(@pstack, $ESCAPE);
  2054.           }
  2055.         }
  2056.  
  2057.     push(@pstack, $var);
  2058.     
  2059.       } elsif ($which eq 'TMPL_LOOP') {
  2060.     # we've got a loop start
  2061.     $options->{debug} and print STDERR "### HTML::Template Debug ### $fname : line $fcounter : LOOP $name start\n";
  2062.     
  2063.     # if we already have this loop, then simply link to the existing
  2064.     # HTML::Template::LOOP, else create a new one.
  2065.     my $loop;
  2066.     if (exists $pmap{$name}) {
  2067.       $loop = $pmap{$name};
  2068.       (ref($loop) eq 'HTML::Template::LOOP') or
  2069.         die "HTML::Template->new() : Already used param name $name as a TMPL_VAR, TMPL_IF or TMPL_UNLESS, found in a TMP_LOOP at $fname : line $fcounter!";
  2070.       
  2071.     } else {
  2072.       # store the results in a LOOP object - actually just a
  2073.       # thin wrapper around another HTML::Template object.
  2074.       $loop = HTML::Template::LOOP->new();
  2075.       $pmap{$name} = $loop;
  2076.     }
  2077.     
  2078.     # get it on the loopstack, pstack of the enclosing block
  2079.     push(@pstack, $loop);
  2080.     push(@loopstack, [$loop, $#pstack]);
  2081.     
  2082.     # magic time - push on a fresh pmap and pstack, adjust the typeglobs.
  2083.     # this gives the loop a separate namespace (i.e. pmap and pstack).
  2084.     push(@pstacks, []);
  2085.     *pstack = $pstacks[$#pstacks];
  2086.     push(@pmaps, {});
  2087.     *pmap = $pmaps[$#pmaps];
  2088.     push(@ifstacks, []);
  2089.     *ifstack = $ifstacks[$#ifstacks];
  2090.     push(@ucstacks, []);
  2091.     *ucstack = $ucstacks[$#ucstacks];
  2092.     
  2093.     # auto-vivify __FIRST__, __LAST__ and __INNER__ if
  2094.     # loop_context_vars is set.  Otherwise, with
  2095.     # die_on_bad_params set output() will might cause errors
  2096.     # when it tries to set them.
  2097.     if ($options->{loop_context_vars}) {
  2098.       $pmap{__first__}   = HTML::Template::VAR->new();
  2099.       $pmap{__inner__}   = HTML::Template::VAR->new();
  2100.       $pmap{__last__}    = HTML::Template::VAR->new();
  2101.       $pmap{__odd__}     = HTML::Template::VAR->new();
  2102.       $pmap{__counter__} = HTML::Template::VAR->new();
  2103.     }
  2104.     
  2105.       } elsif ($which eq '/TMPL_LOOP') {
  2106.     $options->{debug} and print STDERR "### HTML::Template Debug ### $fname : line $fcounter : LOOP end\n";
  2107.     
  2108.     my $loopdata = pop(@loopstack);
  2109.     die "HTML::Template->new() : found </TMPL_LOOP> with no matching <TMPL_LOOP> at $fname : line $fcounter!" unless defined $loopdata;
  2110.     
  2111.     my ($loop, $starts_at) = @$loopdata;
  2112.     
  2113.     # resolve pending conditionals
  2114.     foreach my $uc (@ucstack) {
  2115.       my $var = $uc->[HTML::Template::COND::VARIABLE]; 
  2116.       if (exists($pmap{$var})) {
  2117.         $uc->[HTML::Template::COND::VARIABLE] = $pmap{$var};
  2118.       } else {
  2119.         $pmap{$var} = HTML::Template::VAR->new();
  2120.         $top_pmap{$var} = HTML::Template::VAR->new()
  2121.           if $options->{global_vars} and not exists $top_pmap{$var};
  2122.         $uc->[HTML::Template::COND::VARIABLE] = $pmap{$var};
  2123.       }
  2124.       if (ref($pmap{$var}) eq 'HTML::Template::VAR') {
  2125.         $uc->[HTML::Template::COND::VARIABLE_TYPE] = HTML::Template::COND::VARIABLE_TYPE_VAR;
  2126.       } else {
  2127.         $uc->[HTML::Template::COND::VARIABLE_TYPE] = HTML::Template::COND::VARIABLE_TYPE_LOOP;
  2128.       }
  2129.     }
  2130.     
  2131.     # get pmap and pstack for the loop, adjust the typeglobs to
  2132.     # the enclosing block.
  2133.     my $param_map = pop(@pmaps);
  2134.     *pmap = $pmaps[$#pmaps];
  2135.     my $parse_stack = pop(@pstacks);
  2136.     *pstack = $pstacks[$#pstacks];
  2137.     
  2138.     scalar(@ifstack) and die "HTML::Template->new() : Dangling <TMPL_IF> or <TMPL_UNLESS> in loop ending at $fname : line $fcounter.";
  2139.     pop(@ifstacks);
  2140.     *ifstack = $ifstacks[$#ifstacks];
  2141.     pop(@ucstacks);
  2142.     *ucstack = $ucstacks[$#ucstacks];
  2143.     
  2144.     # instantiate the sub-Template, feeding it parse_stack and
  2145.     # param_map.  This means that only the enclosing template
  2146.     # does _parse() - sub-templates get their parse_stack and
  2147.     # param_map fed to them already filled in.
  2148.     $loop->[HTML::Template::LOOP::TEMPLATE_HASH]{$starts_at}             
  2149.       = ref($self)->_new_from_loop(
  2150.                        parse_stack => $parse_stack,
  2151.                        param_map => $param_map,
  2152.                        debug => $options->{debug}, 
  2153.                        die_on_bad_params => $options->{die_on_bad_params}, 
  2154.                        loop_context_vars => $options->{loop_context_vars},
  2155.                                            case_sensitive => $options->{case_sensitive},
  2156.                                            force_untaint => $options->{force_untaint},
  2157.                                            parent_global_vars => ($options->{global_vars} || $options->{parent_global_vars} || 0)
  2158.                       );
  2159.     
  2160.       } elsif ($which eq 'TMPL_IF' or $which eq 'TMPL_UNLESS' ) {
  2161.     $options->{debug} and print STDERR "### HTML::Template Debug ### $fname : line $fcounter : $which $name start\n";
  2162.     
  2163.     # if we already have this var, then simply link to the existing
  2164.     # HTML::Template::VAR/LOOP, else defer the mapping
  2165.     my $var;        
  2166.     if (exists $pmap{$name}) {
  2167.       $var = $pmap{$name};
  2168.     } else {
  2169.       $var = $name;
  2170.     }
  2171.     
  2172.     # connect the var to a conditional
  2173.     my $cond = HTML::Template::COND->new($var);
  2174.     if ($which eq 'TMPL_IF') {
  2175.       $cond->[HTML::Template::COND::WHICH] = HTML::Template::COND::WHICH_IF;
  2176.       $cond->[HTML::Template::COND::JUMP_IF_TRUE] = 0;
  2177.     } else {
  2178.       $cond->[HTML::Template::COND::WHICH] = HTML::Template::COND::WHICH_UNLESS;
  2179.       $cond->[HTML::Template::COND::JUMP_IF_TRUE] = 1;
  2180.     }
  2181.     
  2182.     # push unconnected conditionals onto the ucstack for
  2183.     # resolution later.  Otherwise, save type information now.
  2184.     if ($var eq $name) {
  2185.       push(@ucstack, $cond);
  2186.     } else {
  2187.       if (ref($var) eq 'HTML::Template::VAR') {
  2188.         $cond->[HTML::Template::COND::VARIABLE_TYPE] = HTML::Template::COND::VARIABLE_TYPE_VAR;
  2189.       } else {
  2190.         $cond->[HTML::Template::COND::VARIABLE_TYPE] = HTML::Template::COND::VARIABLE_TYPE_LOOP;
  2191.       }
  2192.     }
  2193.     
  2194.     # push what we've got onto the stacks
  2195.     push(@pstack, $cond);
  2196.     push(@ifstack, $cond);
  2197.     
  2198.       } elsif ($which eq '/TMPL_IF' or $which eq '/TMPL_UNLESS') {
  2199.     $options->{debug} and print STDERR "### HTML::Template Debug ### $fname : line $fcounter : $which end\n";
  2200.     
  2201.     my $cond = pop(@ifstack);
  2202.     die "HTML::Template->new() : found </${which}> with no matching <TMPL_IF> at $fname : line $fcounter." unless defined $cond;
  2203.     if ($which eq '/TMPL_IF') {
  2204.       die "HTML::Template->new() : found </TMPL_IF> incorrectly terminating a <TMPL_UNLESS> (use </TMPL_UNLESS>) at $fname : line $fcounter.\n" 
  2205.         if ($cond->[HTML::Template::COND::WHICH] == HTML::Template::COND::WHICH_UNLESS);
  2206.     } else {
  2207.       die "HTML::Template->new() : found </TMPL_UNLESS> incorrectly terminating a <TMPL_IF> (use </TMPL_IF>) at $fname : line $fcounter.\n" 
  2208.         if ($cond->[HTML::Template::COND::WHICH] == HTML::Template::COND::WHICH_IF);
  2209.     }
  2210.     
  2211.     # connect the matching to this "address" - place a NOOP to
  2212.     # hold the spot.  This allows output() to treat an IF in the
  2213.     # assembler-esque "Conditional Jump" mode.
  2214.     push(@pstack, $NOOP);
  2215.     $cond->[HTML::Template::COND::JUMP_ADDRESS] = $#pstack;
  2216.     
  2217.       } elsif ($which eq 'TMPL_ELSE') {
  2218.     $options->{debug} and print STDERR "### HTML::Template Debug ### $fname : line $fcounter : ELSE\n";
  2219.     
  2220.     my $cond = pop(@ifstack);
  2221.     die "HTML::Template->new() : found <TMPL_ELSE> with no matching <TMPL_IF> or <TMPL_UNLESS> at $fname : line $fcounter." unless defined $cond;
  2222.         die "HTML::Template->new() : found second <TMPL_ELSE> tag for  <TMPL_IF> or <TMPL_UNLESS> at $fname : line $fcounter." if $cond->[HTML::Template::COND::IS_ELSE];    
  2223.     
  2224.     my $else = HTML::Template::COND->new($cond->[HTML::Template::COND::VARIABLE]);
  2225.     $else->[HTML::Template::COND::WHICH] = $cond->[HTML::Template::COND::WHICH];
  2226.         $else->[HTML::Template::COND::UNCONDITIONAL_JUMP] = 1;
  2227.     $else->[HTML::Template::COND::IS_ELSE] = 1;
  2228.  
  2229.     # need end-block resolution?
  2230.     if (defined($cond->[HTML::Template::COND::VARIABLE_TYPE])) {
  2231.       $else->[HTML::Template::COND::VARIABLE_TYPE] = $cond->[HTML::Template::COND::VARIABLE_TYPE];
  2232.     } else {
  2233.       push(@ucstack, $else);
  2234.     }
  2235.     
  2236.     push(@pstack, $else);
  2237.     push(@ifstack, $else);
  2238.     
  2239.     # connect the matching to this "address" - thus the if,
  2240.     # failing jumps to the ELSE address.  The else then gets
  2241.     # elaborated, and of course succeeds.  On the other hand, if
  2242.     # the IF fails and falls though, output will reach the else
  2243.     # and jump to the /if address.
  2244.     $cond->[HTML::Template::COND::JUMP_ADDRESS] = $#pstack;
  2245.         
  2246.       } elsif ($which eq 'TMPL_INCLUDE') {
  2247.     # handle TMPL_INCLUDEs
  2248.     $options->{debug} and print STDERR "### HTML::Template Debug ### $fname : line $fcounter : INCLUDE $name \n";
  2249.     
  2250.     # no includes here, bub
  2251.     $options->{no_includes} and croak("HTML::Template : Illegal attempt to use TMPL_INCLUDE in template file : (no_includes => 1)");
  2252.     
  2253.     my $filename = $name;
  2254.     
  2255.     # look for the included file...
  2256.     my $filepath;
  2257.     if ($options->{search_path_on_include}) {
  2258.       $filepath = $self->_find_file($filename);
  2259.     } else {
  2260.       $filepath = $self->_find_file($filename, 
  2261.                     [File::Spec->splitdir($fstack[-1][0])]
  2262.                        );
  2263.     }
  2264.     die "HTML::Template->new() : Cannot open included file $filename : file not found."
  2265.       unless defined($filepath);
  2266.     die "HTML::Template->new() : Cannot open included file $filename : $!"
  2267.       unless defined(open(TEMPLATE, $filepath));              
  2268.     
  2269.     # read into the array
  2270.     my $included_template = "";
  2271.         while(read(TEMPLATE, $included_template, 10240, length($included_template))) {}
  2272.     close(TEMPLATE);
  2273.     
  2274.     # call filters if necessary
  2275.     $self->_call_filters(\$included_template) if @{$options->{filter}};
  2276.     
  2277.     if ($included_template) { # not empty
  2278.       # handle the old vanguard format - this needs to happen here
  2279.       # since we're not about to do a next CHUNKS.
  2280.       $options->{vanguard_compatibility_mode} and 
  2281.         $included_template =~ s/%([-\w\/\.+]+)%/<TMPL_VAR NAME=$1>/g;
  2282.       
  2283.       # collect mtimes for included files
  2284.       if ($options->{cache} and !$options->{blind_cache}) {
  2285.         $self->{included_mtimes}{$filepath} = (stat($filepath))[9];
  2286.       }
  2287.       
  2288.       # adjust the fstack to point to the included file info
  2289.       push(@fstack, [$filepath, 1,
  2290.              scalar @{[$included_template =~ m/(\n)/g]} + 1]);
  2291.       (*fname, *fcounter, *fmax) = \ ( @{$fstack[$#fstack]} );
  2292.       
  2293.           # make sure we aren't infinitely recursing
  2294.           die "HTML::Template->new() : likely recursive includes - parsed $options->{max_includes} files deep and giving up (set max_includes higher to allow deeper recursion)." if ($options->{max_includes} and (scalar(@fstack) > $options->{max_includes}));
  2295.           
  2296.       # stick the remains of this chunk onto the bottom of the
  2297.       # included text.
  2298.       $included_template .= $post;
  2299.       $post = undef;
  2300.       
  2301.       # move the new chunks into place.  
  2302.       splice(@chunks, $chunk_number, 1,
  2303.          split(m/(?=<)/, $included_template));
  2304.  
  2305.       # recalculate stopping point
  2306.       $last_chunk = $#chunks;
  2307.  
  2308.       # start in on the first line of the included text - nothing
  2309.       # else to do on this line.
  2310.       $chunk = $chunks[$chunk_number];
  2311.  
  2312.       redo CHUNK;
  2313.     }
  2314.       } else {
  2315.     # zuh!?
  2316.     die "HTML::Template->new() : Unknown or unmatched TMPL construct at $fname : line $fcounter.";
  2317.       }
  2318.       # push the rest after the tag
  2319.       if (defined($post)) {
  2320.     if (ref($pstack[$#pstack]) eq 'SCALAR') {
  2321.       ${$pstack[$#pstack]} .= $post;
  2322.     } else {
  2323.       push(@pstack, \$post);
  2324.     }
  2325.       }
  2326.     } else { # just your ordinary markup
  2327.       # make sure we didn't reject something TMPL_* but badly formed
  2328.       if ($options->{strict}) {
  2329.     die "HTML::Template->new() : Syntax error in <TMPL_*> tag at $fname : $fcounter." if ($chunk =~ /<(?:!--\s*)?\/?[Tt][Mm][Pp][Ll]_/);
  2330.       }
  2331.       
  2332.       # push the rest and get next chunk
  2333.       if (defined($chunk)) {
  2334.     if (ref($pstack[$#pstack]) eq 'SCALAR') {
  2335.       ${$pstack[$#pstack]} .= $chunk;
  2336.     } else {
  2337.       push(@pstack, \$chunk);
  2338.     }
  2339.       }
  2340.     }
  2341.     # count newlines in chunk and advance line count
  2342.     $fcounter += scalar(@{[$chunk =~ m/(\n)/g]});
  2343.     # if we just crossed the end of an included file
  2344.     # pop off the record and re-alias to the enclosing file's info
  2345.     pop(@fstack), (*fname, *fcounter, *fmax) = \ ( @{$fstack[$#fstack]} )
  2346.       if ($fcounter > $fmax);
  2347.     
  2348.   } # next CHUNK
  2349.  
  2350.   # make sure we don't have dangling IF or LOOP blocks
  2351.   scalar(@ifstack) and die "HTML::Template->new() : At least one <TMPL_IF> or <TMPL_UNLESS> not terminated at end of file!";
  2352.   scalar(@loopstack) and die "HTML::Template->new() : At least one <TMPL_LOOP> not terminated at end of file!";
  2353.  
  2354.   # resolve pending conditionals
  2355.   foreach my $uc (@ucstack) {
  2356.     my $var = $uc->[HTML::Template::COND::VARIABLE]; 
  2357.     if (exists($pmap{$var})) {
  2358.       $uc->[HTML::Template::COND::VARIABLE] = $pmap{$var};
  2359.     } else {
  2360.       $pmap{$var} = HTML::Template::VAR->new();
  2361.       $top_pmap{$var} = HTML::Template::VAR->new()
  2362.         if $options->{global_vars} and not exists $top_pmap{$var};
  2363.       $uc->[HTML::Template::COND::VARIABLE] = $pmap{$var};
  2364.     }
  2365.     if (ref($pmap{$var}) eq 'HTML::Template::VAR') {
  2366.       $uc->[HTML::Template::COND::VARIABLE_TYPE] = HTML::Template::COND::VARIABLE_TYPE_VAR;
  2367.     } else {
  2368.       $uc->[HTML::Template::COND::VARIABLE_TYPE] = HTML::Template::COND::VARIABLE_TYPE_LOOP;
  2369.     }
  2370.   }
  2371.  
  2372.   # want a stack dump?
  2373.   if ($options->{stack_debug}) {
  2374.     require 'Data/Dumper.pm';
  2375.     print STDERR "### HTML::Template _param Stack Dump ###\n\n", Data::Dumper::Dumper($self->{parse_stack}), "\n";
  2376.   }
  2377.  
  2378.   # get rid of filters - they cause runtime errors if Storable tries
  2379.   # to store them.  This can happen under global_vars.
  2380.   delete $options->{filter};
  2381. }
  2382.  
  2383. # a recursive sub that associates each loop with the loops above
  2384. # (treating the top-level as a loop)
  2385. sub _globalize_vars {
  2386.   my $self = shift;
  2387.   
  2388.   # associate with the loop (and top-level templates) above in the tree.
  2389.   push(@{$self->{options}{associate}}, @_);
  2390.   
  2391.   # recurse down into the template tree, adding ourself to the end of
  2392.   # list.
  2393.   push(@_, $self);
  2394.   map { $_->_globalize_vars(@_) } 
  2395.     map {values %{$_->[HTML::Template::LOOP::TEMPLATE_HASH]}}
  2396.       grep { ref($_) eq 'HTML::Template::LOOP'} @{$self->{parse_stack}};
  2397. }
  2398.  
  2399. # method used to recursively un-hook associate
  2400. sub _unglobalize_vars {
  2401.   my $self = shift;
  2402.   
  2403.   # disassociate
  2404.   $self->{options}{associate} = undef;
  2405.   
  2406.   # recurse down into the template tree disassociating
  2407.   map { $_->_unglobalize_vars() } 
  2408.     map {values %{$_->[HTML::Template::LOOP::TEMPLATE_HASH]}}
  2409.       grep { ref($_) eq 'HTML::Template::LOOP'} @{$self->{parse_stack}};
  2410. }
  2411.  
  2412. =head2 param()
  2413.  
  2414. C<param()> can be called in a number of ways
  2415.  
  2416. 1) To return a list of parameters in the template : 
  2417.  
  2418.    my @parameter_names = $self->param();
  2419.    
  2420.  
  2421. 2) To return the value set to a param : 
  2422.  
  2423.    my $value = $self->param('PARAM');
  2424.  
  2425. 3) To set the value of a parameter :
  2426.  
  2427.       # For simple TMPL_VARs:
  2428.       $self->param(PARAM => 'value');
  2429.  
  2430.       # with a subroutine reference that gets called to get the value
  2431.       # of the scalar.  The sub will recieve the template object as a
  2432.       # parameter.
  2433.       $self->param(PARAM => sub { return 'value' });   
  2434.  
  2435.       # And TMPL_LOOPs:
  2436.       $self->param(LOOP_PARAM => 
  2437.                    [ 
  2438.                     { PARAM => VALUE_FOR_FIRST_PASS, ... }, 
  2439.                     { PARAM => VALUE_FOR_SECOND_PASS, ... } 
  2440.                     ...
  2441.                    ]
  2442.                   );
  2443.  
  2444. 4) To set the value of a a number of parameters :
  2445.  
  2446.      # For simple TMPL_VARs:
  2447.      $self->param(PARAM => 'value', 
  2448.                   PARAM2 => 'value'
  2449.                  );
  2450.  
  2451.       # And with some TMPL_LOOPs:
  2452.       $self->param(PARAM => 'value', 
  2453.                    PARAM2 => 'value',
  2454.                    LOOP_PARAM => 
  2455.                    [ 
  2456.                     { PARAM => VALUE_FOR_FIRST_PASS, ... }, 
  2457.                     { PARAM => VALUE_FOR_SECOND_PASS, ... } 
  2458.                     ...
  2459.                    ],
  2460.                    ANOTHER_LOOP_PARAM => 
  2461.                    [ 
  2462.                     { PARAM => VALUE_FOR_FIRST_PASS, ... }, 
  2463.                     { PARAM => VALUE_FOR_SECOND_PASS, ... } 
  2464.                     ...
  2465.                    ]
  2466.                   );
  2467.  
  2468. 5) To set the value of a a number of parameters using a hash-ref :
  2469.  
  2470.       $self->param(
  2471.                    { 
  2472.                       PARAM => 'value', 
  2473.                       PARAM2 => 'value',
  2474.                       LOOP_PARAM => 
  2475.                       [ 
  2476.                         { PARAM => VALUE_FOR_FIRST_PASS, ... }, 
  2477.                         { PARAM => VALUE_FOR_SECOND_PASS, ... } 
  2478.                         ...
  2479.                       ],
  2480.                       ANOTHER_LOOP_PARAM => 
  2481.                       [ 
  2482.                         { PARAM => VALUE_FOR_FIRST_PASS, ... }, 
  2483.                         { PARAM => VALUE_FOR_SECOND_PASS, ... } 
  2484.                         ...
  2485.                       ]
  2486.                     }
  2487.                    );
  2488.  
  2489. An error occurs if you try to set a value that is tainted if the "force_untaint"
  2490. option is set.
  2491.  
  2492. =cut
  2493.  
  2494.  
  2495. sub param {
  2496.   my $self = shift;
  2497.   my $options = $self->{options};
  2498.   my $param_map = $self->{param_map};
  2499.  
  2500.   # the no-parameter case - return list of parameters in the template.
  2501.   return keys(%$param_map) unless scalar(@_);
  2502.   
  2503.   my $first = shift;
  2504.   my $type = ref $first;
  2505.  
  2506.   # the one-parameter case - could be a parameter value request or a
  2507.   # hash-ref.
  2508.   if (!scalar(@_) and !length($type)) {
  2509.     my $param = $options->{case_sensitive} ? $first : lc $first;
  2510.     
  2511.     # check for parameter existence 
  2512.     $options->{die_on_bad_params} and !exists($param_map->{$param}) and
  2513.       croak("HTML::Template : Attempt to get nonexistent parameter '$param' - this parameter name doesn't match any declarations in the template file : (die_on_bad_params set => 1)");
  2514.     
  2515.     return undef unless (exists($param_map->{$param}) and
  2516.                          defined($param_map->{$param}));
  2517.  
  2518.     return ${$param_map->{$param}} if 
  2519.       (ref($param_map->{$param}) eq 'HTML::Template::VAR');
  2520.     return $param_map->{$param}[HTML::Template::LOOP::PARAM_SET];
  2521.   } 
  2522.  
  2523.   if (!scalar(@_)) {
  2524.     croak("HTML::Template->param() : Single reference arg to param() must be a hash-ref!  You gave me a $type.")
  2525.         unless $type eq 'HASH' or UNIVERSAL::isa($first, 'HASH');
  2526.     push(@_, %$first);
  2527.   } else {
  2528.     unshift(@_, $first);
  2529.   }
  2530.   
  2531.   croak("HTML::Template->param() : You gave me an odd number of parameters to param()!")
  2532.     unless ((@_ % 2) == 0);
  2533.  
  2534.   # strangely, changing this to a "while(@_) { shift, shift }" type
  2535.   # loop causes perl 5.004_04 to die with some nonsense about a
  2536.   # read-only value.
  2537.   for (my $x = 0; $x <= $#_; $x += 2) {
  2538.     my $param = $options->{case_sensitive} ? $_[$x] : lc $_[$x];
  2539.     my $value = $_[($x + 1)];
  2540.     
  2541.     # check that this param exists in the template
  2542.     $options->{die_on_bad_params} and !exists($param_map->{$param}) and
  2543.       croak("HTML::Template : Attempt to set nonexistent parameter '$param' - this parameter name doesn't match any declarations in the template file : (die_on_bad_params => 1)");
  2544.     
  2545.     # if we're not going to die from bad param names, we need to ignore
  2546.     # them...
  2547.     unless (exists($param_map->{$param})) {
  2548.         next if not $options->{parent_global_vars};
  2549.  
  2550.         # ... unless global vars is on - in which case we can't be
  2551.         # sure we won't need it in a lower loop.
  2552.         if (ref($value) eq 'ARRAY') {
  2553.             $param_map->{$param} = HTML::Template::LOOP->new();
  2554.         } else {
  2555.             $param_map->{$param} = HTML::Template::VAR->new();
  2556.         }
  2557.     }
  2558.  
  2559.     
  2560.     # figure out what we've got, taking special care to allow for
  2561.     # objects that are compatible underneath.
  2562.     my $value_type = ref($value);
  2563.     if (defined($value_type) and length($value_type) and ($value_type eq 'ARRAY' or ((ref($value) !~ /^(CODE)|(HASH)|(SCALAR)$/) and $value->isa('ARRAY')))) {
  2564.       (ref($param_map->{$param}) eq 'HTML::Template::LOOP') or
  2565.         croak("HTML::Template::param() : attempt to set parameter '$param' with an array ref - parameter is not a TMPL_LOOP!");
  2566.       $param_map->{$param}[HTML::Template::LOOP::PARAM_SET] = [@{$value}];
  2567.     } else {
  2568.       (ref($param_map->{$param}) eq 'HTML::Template::VAR') or
  2569.         croak("HTML::Template::param() : attempt to set parameter '$param' with a scalar - parameter is not a TMPL_VAR!");
  2570.       ${$param_map->{$param}} = $value;
  2571.     }
  2572.   }
  2573. }
  2574.  
  2575. =pod
  2576.  
  2577. =head2 clear_params()
  2578.  
  2579. Sets all the parameters to undef.  Useful internally, if nowhere else!
  2580.  
  2581. =cut
  2582.  
  2583. sub clear_params {
  2584.   my $self = shift;
  2585.   my $type;
  2586.   foreach my $name (keys %{$self->{param_map}}) {
  2587.     $type = ref($self->{param_map}{$name});
  2588.     undef(${$self->{param_map}{$name}})
  2589.       if ($type eq 'HTML::Template::VAR');
  2590.     undef($self->{param_map}{$name}[HTML::Template::LOOP::PARAM_SET])
  2591.       if ($type eq 'HTML::Template::LOOP');    
  2592.   }
  2593. }
  2594.  
  2595.  
  2596. # obsolete implementation of associate
  2597. sub associateCGI { 
  2598.   my $self = shift;
  2599.   my $cgi  = shift;
  2600.   (ref($cgi) eq 'CGI') or
  2601.     croak("Warning! non-CGI object was passed to HTML::Template::associateCGI()!\n");
  2602.   push(@{$self->{options}{associate}}, $cgi);
  2603.   return 1;
  2604. }
  2605.  
  2606.  
  2607. =head2 output()
  2608.  
  2609. output() returns the final result of the template.  In most situations
  2610. you'll want to print this, like:
  2611.  
  2612.    print $template->output();
  2613.  
  2614. When output is called each occurrence of <TMPL_VAR NAME=name> is
  2615. replaced with the value assigned to "name" via C<param()>.  If a named
  2616. parameter is unset it is simply replaced with ''.  <TMPL_LOOPS> are
  2617. evaluated once per parameter set, accumlating output on each pass.
  2618.  
  2619. Calling output() is guaranteed not to change the state of the
  2620. Template object, in case you were wondering.  This property is mostly
  2621. important for the internal implementation of loops.
  2622.  
  2623. You may optionally supply a filehandle to print to automatically as
  2624. the template is generated.  This may improve performance and lower
  2625. memory consumption.  Example:
  2626.  
  2627.    $template->output(print_to => *STDOUT);
  2628.  
  2629. The return value is undefined when using the C<print_to> option.
  2630.  
  2631. =cut
  2632.  
  2633. use vars qw(%URLESCAPE_MAP);
  2634. sub output {
  2635.   my $self = shift;
  2636.   my $options = $self->{options};
  2637.   local $_;
  2638.  
  2639.   croak("HTML::Template->output() : You gave me an odd number of parameters to output()!")
  2640.     unless ((@_ % 2) == 0);
  2641.   my %args = @_;
  2642.  
  2643.   print STDERR "### HTML::Template Memory Debug ### START OUTPUT ", $self->{proc_mem}->size(), "\n"
  2644.     if $options->{memory_debug};
  2645.  
  2646.   $options->{debug} and print STDERR "### HTML::Template Debug ### In output\n";
  2647.  
  2648.   # want a stack dump?
  2649.   if ($options->{stack_debug}) {
  2650.     require 'Data/Dumper.pm';
  2651.     print STDERR "### HTML::Template output Stack Dump ###\n\n", Data::Dumper::Dumper($self->{parse_stack}), "\n";
  2652.   }
  2653.  
  2654.   # globalize vars - this happens here to localize the circular
  2655.   # references created by global_vars.
  2656.   $self->_globalize_vars() if ($options->{global_vars});
  2657.  
  2658.   # support the associate magic, searching for undefined params and
  2659.   # attempting to fill them from the associated objects.
  2660.   if (scalar(@{$options->{associate}})) {
  2661.     # prepare case-mapping hashes to do case-insensitive matching
  2662.     # against associated objects.  This allows CGI.pm to be
  2663.     # case-sensitive and still work with asssociate.
  2664.     my (%case_map, $lparam);
  2665.     foreach my $associated_object (@{$options->{associate}}) {
  2666.       # what a hack!  This should really be optimized out for case_sensitive.
  2667.       if ($options->{case_sensitive}) {
  2668.         map {
  2669.           $case_map{$associated_object}{$_} = $_
  2670.         } $associated_object->param();
  2671.       } else {
  2672.         map {
  2673.           $case_map{$associated_object}{lc($_)} = $_
  2674.         } $associated_object->param();
  2675.       }
  2676.     }
  2677.  
  2678.     foreach my $param (keys %{$self->{param_map}}) {
  2679.       unless (defined($self->param($param))) {
  2680.       OBJ: foreach my $associated_object (reverse @{$options->{associate}}) {
  2681.           $self->param($param, scalar $associated_object->param($case_map{$associated_object}{$param})), last OBJ
  2682.             if (exists($case_map{$associated_object}{$param}));
  2683.         }
  2684.       }
  2685.     }
  2686.   }
  2687.  
  2688.   use vars qw($line @parse_stack); local(*line, *parse_stack);
  2689.  
  2690.   # walk the parse stack, accumulating output in $result
  2691.   *parse_stack = $self->{parse_stack};
  2692.   my $result = '';
  2693.  
  2694.   tie $result, 'HTML::Template::PRINTSCALAR', $args{print_to}
  2695.     if defined $args{print_to} and not tied $args{print_to};
  2696.     
  2697.   my $type;
  2698.   my $parse_stack_length = $#parse_stack;
  2699.   for (my $x = 0; $x <= $parse_stack_length; $x++) {
  2700.     *line = \$parse_stack[$x];
  2701.     $type = ref($line);
  2702.     
  2703.     if ($type eq 'SCALAR') {
  2704.       $result .= $$line;
  2705.     } elsif ($type eq 'HTML::Template::VAR' and ref($$line) eq 'CODE') {
  2706.       if ( defined($$line) ) {
  2707.         if ($options->{force_untaint}) {
  2708.           my $tmp = $$line->($self);
  2709.           croak("HTML::Template->output() : 'force_untaint' option but coderef returns tainted value")
  2710.             if tainted($tmp);
  2711.           $result .= $tmp;
  2712.         } else {
  2713.           $result .= $$line->($self);
  2714.         }
  2715.       }
  2716.     } elsif ($type eq 'HTML::Template::VAR') {
  2717.       if (defined $$line) {
  2718.         if ($options->{force_untaint} && tainted($$line)) {
  2719.           croak("HTML::Template->output() : tainted value with 'force_untaint' option");
  2720.         }
  2721.         $result .= $$line;
  2722.       }
  2723.     } elsif ($type eq 'HTML::Template::LOOP') {
  2724.       if (defined($line->[HTML::Template::LOOP::PARAM_SET])) {
  2725.         eval { $result .= $line->output($x, $options->{loop_context_vars}); };
  2726.         croak("HTML::Template->output() : fatal error in loop output : $@") 
  2727.           if $@;
  2728.       }
  2729.     } elsif ($type eq 'HTML::Template::COND') {
  2730.         
  2731.      if ($line->[HTML::Template::COND::UNCONDITIONAL_JUMP]) {
  2732.        $x = $line->[HTML::Template::COND::JUMP_ADDRESS]
  2733.      } else {
  2734.         if ($line->[HTML::Template::COND::JUMP_IF_TRUE]) {
  2735.           if ($line->[HTML::Template::COND::VARIABLE_TYPE] == HTML::Template::COND::VARIABLE_TYPE_VAR) {
  2736.             if (defined ${$line->[HTML::Template::COND::VARIABLE]}) {
  2737.               if (ref(${$line->[HTML::Template::COND::VARIABLE]}) eq 'CODE') {
  2738.                 $x = $line->[HTML::Template::COND::JUMP_ADDRESS] if ${$line->[HTML::Template::COND::VARIABLE]}->($self);
  2739.               } else {
  2740.                 $x = $line->[HTML::Template::COND::JUMP_ADDRESS] if ${$line->[HTML::Template::COND::VARIABLE]};
  2741.               }
  2742.             }
  2743.           } else {
  2744.             $x = $line->[HTML::Template::COND::JUMP_ADDRESS] if
  2745.               (defined $line->[HTML::Template::COND::VARIABLE][HTML::Template::LOOP::PARAM_SET] and
  2746.                scalar @{$line->[HTML::Template::COND::VARIABLE][HTML::Template::LOOP::PARAM_SET]});
  2747.           }
  2748.         } else {
  2749.           if ($line->[HTML::Template::COND::VARIABLE_TYPE] == HTML::Template::COND::VARIABLE_TYPE_VAR) {
  2750.             if (defined ${$line->[HTML::Template::COND::VARIABLE]}) {
  2751.               if (ref(${$line->[HTML::Template::COND::VARIABLE]}) eq 'CODE') {
  2752.                 $x = $line->[HTML::Template::COND::JUMP_ADDRESS] unless ${$line->[HTML::Template::COND::VARIABLE]}->($self);
  2753.               } else {
  2754.                 $x = $line->[HTML::Template::COND::JUMP_ADDRESS] unless ${$line->[HTML::Template::COND::VARIABLE]};
  2755.               }
  2756.             } else {
  2757.               $x = $line->[HTML::Template::COND::JUMP_ADDRESS];
  2758.             }
  2759.           } else {
  2760.             $x = $line->[HTML::Template::COND::JUMP_ADDRESS] if
  2761.               (not defined $line->[HTML::Template::COND::VARIABLE][HTML::Template::LOOP::PARAM_SET] or
  2762.                not scalar @{$line->[HTML::Template::COND::VARIABLE][HTML::Template::LOOP::PARAM_SET]});
  2763.           }
  2764.         }
  2765.       }          
  2766.     } elsif ($type eq 'HTML::Template::NOOP') {
  2767.       next;
  2768.     } elsif ($type eq 'HTML::Template::DEFAULT') {
  2769.       $_ = $x;  # remember default place in stack
  2770.  
  2771.       # find next VAR, there might be an ESCAPE in the way
  2772.       *line = \$parse_stack[++$x];
  2773.       *line = \$parse_stack[++$x] 
  2774.         if ref $line eq 'HTML::Template::ESCAPE' or
  2775.            ref $line eq 'HTML::Template::JSESCAPE' or
  2776.            ref $line eq 'HTML::Template::URLESCAPE';
  2777.  
  2778.       # either output the default or go back
  2779.       if (defined $$line) {
  2780.         $x = $_;
  2781.       } else {
  2782.         $result .= ${$parse_stack[$_]};
  2783.       }
  2784.       next;      
  2785.     } elsif ($type eq 'HTML::Template::ESCAPE') {
  2786.       *line = \$parse_stack[++$x];
  2787.       if (defined($$line)) {
  2788.         if (ref($$line) eq 'CODE') {
  2789.             $_ = $$line->($self);
  2790.             if ($options->{force_untaint} > 1 && tainted($_)) {
  2791.               croak("HTML::Template->output() : 'force_untaint' option but coderef returns tainted value");
  2792.             }
  2793.         } else {
  2794.             $_ = $$line;
  2795.             if ($options->{force_untaint} > 1 && tainted($_)) {
  2796.               croak("HTML::Template->output() : tainted value with 'force_untaint' option");
  2797.             }
  2798.         }
  2799.         
  2800.         # straight from the CGI.pm bible.
  2801.         s/&/&/g;
  2802.         s/\"/"/g; #"
  2803.         s/>/>/g;
  2804.         s/</</g;
  2805.         s/'/'/g; #'
  2806.         
  2807.         $result .= $_;
  2808.       }
  2809.       next;
  2810.     } elsif ($type eq 'HTML::Template::JSESCAPE') {
  2811.       $x++;
  2812.       *line = \$parse_stack[$x];
  2813.       if (defined($$line)) {
  2814.         if (ref($$line) eq 'CODE') {
  2815.             $_ = $$line->($self);
  2816.             if ($options->{force_untaint} > 1 && tainted($_)) {
  2817.               croak("HTML::Template->output() : 'force_untaint' option but coderef returns tainted value");
  2818.             }
  2819.         } else {
  2820.             $_ = $$line;
  2821.             if ($options->{force_untaint} > 1 && tainted($_)) {
  2822.               croak("HTML::Template->output() : tainted value with 'force_untaint' option");
  2823.             }
  2824.         }
  2825.         s/\\/\\\\/g;
  2826.         s/'/\\'/g;
  2827.         s/"/\\"/g;
  2828.         s/\n/\\n/g;
  2829.         s/\r/\\r/g;
  2830.         $result .= $_;
  2831.       }
  2832.     } elsif ($type eq 'HTML::Template::URLESCAPE') {
  2833.       $x++;
  2834.       *line = \$parse_stack[$x];
  2835.       if (defined($$line)) {
  2836.         if (ref($$line) eq 'CODE') {
  2837.             $_ = $$line->($self);
  2838.             if ($options->{force_untaint} > 1 && tainted($_)) {
  2839.               croak("HTML::Template->output() : 'force_untaint' option but coderef returns tainted value");
  2840.             }
  2841.         } else {
  2842.             $_ = $$line;
  2843.             if ($options->{force_untaint} > 1 && tainted($_)) {
  2844.               croak("HTML::Template->output() : tainted value with 'force_untaint' option");
  2845.             }
  2846.         }
  2847.         # Build a char->hex map if one isn't already available
  2848.         unless (exists($URLESCAPE_MAP{chr(1)})) {
  2849.           for (0..255) { $URLESCAPE_MAP{chr($_)} = sprintf('%%%02X', $_); }
  2850.         }
  2851.         # do the translation (RFC 2396 ^uric)
  2852.         s!([^a-zA-Z0-9_.\-])!$URLESCAPE_MAP{$1}!g;
  2853.         $result .= $_;
  2854.       }
  2855.     } else {
  2856.       confess("HTML::Template::output() : Unknown item in parse_stack : " . $type);
  2857.     }
  2858.   }
  2859.  
  2860.   # undo the globalization circular refs
  2861.   $self->_unglobalize_vars() if ($options->{global_vars});
  2862.  
  2863.   print STDERR "### HTML::Template Memory Debug ### END OUTPUT ", $self->{proc_mem}->size(), "\n"
  2864.     if $options->{memory_debug};
  2865.     
  2866.   return undef if defined $args{print_to};
  2867.   return $result;
  2868. }
  2869.  
  2870. =pod
  2871.  
  2872. =head2 query()
  2873.  
  2874. This method allow you to get information about the template structure.
  2875. It can be called in a number of ways.  The simplest usage of query is
  2876. simply to check whether a parameter name exists in the template, using
  2877. the C<name> option:
  2878.  
  2879.   if ($template->query(name => 'foo')) {
  2880.     # do something if a varaible of any type 
  2881.     # named FOO is in the template
  2882.   }
  2883.  
  2884. This same usage returns the type of the parameter.  The type is the
  2885. same as the tag minus the leading 'TMPL_'.  So, for example, a
  2886. TMPL_VAR parameter returns 'VAR' from C<query()>.
  2887.  
  2888.   if ($template->query(name => 'foo') eq 'VAR') {
  2889.     # do something if FOO exists and is a TMPL_VAR
  2890.   }
  2891.  
  2892. Note that the variables associated with TMPL_IFs and TMPL_UNLESSs will
  2893. be identified as 'VAR' unless they are also used in a TMPL_LOOP, in
  2894. which case they will return 'LOOP'.
  2895.  
  2896. C<query()> also allows you to get a list of parameters inside a loop
  2897. (and inside loops inside loops).  Example loop:
  2898.  
  2899.    <TMPL_LOOP NAME="EXAMPLE_LOOP">
  2900.      <TMPL_VAR NAME="BEE">
  2901.      <TMPL_VAR NAME="BOP">
  2902.      <TMPL_LOOP NAME="EXAMPLE_INNER_LOOP">
  2903.        <TMPL_VAR NAME="INNER_BEE">
  2904.        <TMPL_VAR NAME="INNER_BOP">
  2905.      </TMPL_LOOP>
  2906.    </TMPL_LOOP>
  2907.  
  2908. And some query calls:
  2909.   
  2910.   # returns 'LOOP'
  2911.   $type = $template->query(name => 'EXAMPLE_LOOP');
  2912.     
  2913.   # returns ('bop', 'bee', 'example_inner_loop')
  2914.   @param_names = $template->query(loop => 'EXAMPLE_LOOP');
  2915.  
  2916.   # both return 'VAR'
  2917.   $type = $template->query(name => ['EXAMPLE_LOOP', 'BEE']);
  2918.   $type = $template->query(name => ['EXAMPLE_LOOP', 'BOP']);
  2919.  
  2920.   # and this one returns 'LOOP'
  2921.   $type = $template->query(name => ['EXAMPLE_LOOP', 
  2922.                                     'EXAMPLE_INNER_LOOP']);
  2923.   
  2924.   # and finally, this returns ('inner_bee', 'inner_bop')
  2925.   @inner_param_names = $template->query(loop => ['EXAMPLE_LOOP',
  2926.                                                  'EXAMPLE_INNER_LOOP']);
  2927.  
  2928.   # for non existent parameter names you get undef
  2929.   # this returns undef.
  2930.   $type = $template->query(name => 'DWEAZLE_ZAPPA');
  2931.  
  2932.   # calling loop on a non-loop parameter name will cause an error.
  2933.   # this dies:
  2934.   $type = $template->query(loop => 'DWEAZLE_ZAPPA');
  2935.  
  2936. As you can see above the C<loop> option returns a list of parameter
  2937. names and both C<name> and C<loop> take array refs in order to refer
  2938. to parameters inside loops.  It is an error to use C<loop> with a
  2939. parameter that is not a loop.
  2940.  
  2941. Note that all the names are returned in lowercase and the types are
  2942. uppercase.
  2943.  
  2944. Just like C<param()>, C<query()> with no arguments returns all the
  2945. parameter names in the template at the top level.
  2946.  
  2947. =cut
  2948.  
  2949. sub query {
  2950.   my $self = shift;
  2951.   $self->{options}{debug} and print STDERR "### HTML::Template Debug ### query(", join(', ', @_), ")\n";
  2952.  
  2953.   # the no-parameter case - return $self->param()
  2954.   return $self->param() unless scalar(@_);
  2955.   
  2956.   croak("HTML::Template::query() : Odd number of parameters passed to query!")
  2957.     if (scalar(@_) % 2);
  2958.   croak("HTML::Template::query() : Wrong number of parameters passed to query - should be 2.")
  2959.     if (scalar(@_) != 2);
  2960.  
  2961.   my ($opt, $path) = (lc shift, shift);
  2962.   croak("HTML::Template::query() : invalid parameter ($opt)")
  2963.     unless ($opt eq 'name' or $opt eq 'loop');
  2964.  
  2965.   # make path an array unless it already is
  2966.   $path = [$path] unless (ref $path);
  2967.  
  2968.   # find the param in question.
  2969.   my @objs = $self->_find_param(@$path);
  2970.   return undef unless scalar(@objs);
  2971.   my ($obj, $type);
  2972.  
  2973.   # do what the user asked with the object
  2974.   if ($opt eq 'name') {
  2975.     # we only look at the first one.  new() should make sure they're
  2976.     # all the same.
  2977.     ($obj, $type) = (shift(@objs), shift(@objs));
  2978.     return undef unless defined $obj;
  2979.     return 'VAR' if $type eq 'HTML::Template::VAR';
  2980.     return 'LOOP' if $type eq 'HTML::Template::LOOP';
  2981.     croak("HTML::Template::query() : unknown object ($type) in param_map!");
  2982.  
  2983.   } elsif ($opt eq 'loop') {
  2984.     my %results;
  2985.     while(@objs) {
  2986.       ($obj, $type) = (shift(@objs), shift(@objs));
  2987.       croak("HTML::Template::query() : Search path [", join(', ', @$path), "] doesn't end in a TMPL_LOOP - it is an error to use the 'loop' option on a non-loop parameter.  To avoid this problem you can use the 'name' option to query() to check the type first.") 
  2988.         unless ((defined $obj) and ($type eq 'HTML::Template::LOOP'));
  2989.       
  2990.       # SHAZAM!  This bit extracts all the parameter names from all the
  2991.       # loop objects for this name.
  2992.       map {$results{$_} = 1} map { keys(%{$_->{'param_map'}}) }
  2993.         values(%{$obj->[HTML::Template::LOOP::TEMPLATE_HASH]});
  2994.     }
  2995.     # this is our loop list, return it.
  2996.     return keys(%results);   
  2997.   }
  2998. }
  2999.  
  3000. # a function that returns the object(s) corresponding to a given path and
  3001. # its (their) ref()(s).  Used by query() in the obvious way.
  3002. sub _find_param {
  3003.   my $self = shift;
  3004.   my $spot = $self->{options}{case_sensitive} ? shift : lc shift;
  3005.  
  3006.   # get the obj and type for this spot
  3007.   my $obj = $self->{'param_map'}{$spot};
  3008.   return unless defined $obj;
  3009.   my $type = ref $obj;
  3010.  
  3011.   # return if we're here or if we're not but this isn't a loop
  3012.   return ($obj, $type) unless @_;
  3013.   return unless ($type eq 'HTML::Template::LOOP');
  3014.  
  3015.   # recurse.  this is a depth first seach on the template tree, for
  3016.   # the algorithm geeks in the audience.
  3017.   return map { $_->_find_param(@_) }
  3018.     values(%{$obj->[HTML::Template::LOOP::TEMPLATE_HASH]});
  3019. }
  3020.  
  3021. # HTML::Template::VAR, LOOP, etc are *light* objects - their internal
  3022. # spec is used above.  No encapsulation or information hiding is to be
  3023. # assumed.
  3024.  
  3025. package HTML::Template::VAR;
  3026.  
  3027. sub new {
  3028.     my $value;
  3029.     return bless(\$value, $_[0]);
  3030. }
  3031.  
  3032. package HTML::Template::DEFAULT;
  3033.  
  3034. sub new {
  3035.     my $value = $_[1];
  3036.     return bless(\$value, $_[0]);
  3037. }
  3038.  
  3039. package HTML::Template::LOOP;
  3040.  
  3041. sub new {
  3042.     return bless([], $_[0]);
  3043. }
  3044.  
  3045. sub output {
  3046.   my $self = shift;
  3047.   my $index = shift;
  3048.   my $loop_context_vars = shift;
  3049.   my $template = $self->[TEMPLATE_HASH]{$index};
  3050.   my $value_sets_array = $self->[PARAM_SET];
  3051.   return unless defined($value_sets_array);  
  3052.   
  3053.   my $result = '';
  3054.   my $count = 0;
  3055.   my $odd = 0;
  3056.   foreach my $value_set (@$value_sets_array) {
  3057.     if ($loop_context_vars) {
  3058.       if ($count == 0) {
  3059.         @{$value_set}{qw(__first__ __inner__ __last__)} = (1,0,$#{$value_sets_array} == 0);
  3060.       } elsif ($count == $#{$value_sets_array}) {
  3061.         @{$value_set}{qw(__first__ __inner__ __last__)} = (0,0,1);
  3062.       } else {
  3063.         @{$value_set}{qw(__first__ __inner__ __last__)} = (0,1,0);
  3064.       }
  3065.       $odd = $value_set->{__odd__} = not $odd;
  3066.       $value_set->{__counter__} = $count + 1;
  3067.     }
  3068.     $template->param($value_set);    
  3069.     $result .= $template->output;
  3070.     $template->clear_params;
  3071.     @{$value_set}{qw(__first__ __last__ __inner__ __odd__ __counter__)} = 
  3072.       (0,0,0,0)
  3073.         if ($loop_context_vars);
  3074.     $count++;
  3075.   }
  3076.  
  3077.   return $result;
  3078. }
  3079.  
  3080. package HTML::Template::COND;
  3081.  
  3082. sub new {
  3083.   my $pkg = shift;
  3084.   my $var = shift;
  3085.   my $self = [];
  3086.   $self->[VARIABLE] = $var;
  3087.  
  3088.   bless($self, $pkg);  
  3089.   return $self;
  3090. }
  3091.  
  3092. package HTML::Template::NOOP;
  3093. sub new {
  3094.   my $unused;
  3095.   my $self = \$unused;
  3096.   bless($self, $_[0]);
  3097.   return $self;
  3098. }
  3099.  
  3100. package HTML::Template::ESCAPE;
  3101. sub new {
  3102.   my $unused;
  3103.   my $self = \$unused;
  3104.   bless($self, $_[0]);
  3105.   return $self;
  3106. }
  3107.  
  3108. package HTML::Template::JSESCAPE;
  3109. sub new {
  3110.   my $unused;
  3111.   my $self = \$unused;
  3112.   bless($self, $_[0]);
  3113.   return $self;
  3114. }
  3115.  
  3116. package HTML::Template::URLESCAPE;
  3117. sub new {
  3118.   my $unused;
  3119.   my $self = \$unused;
  3120.   bless($self, $_[0]);
  3121.   return $self;
  3122. }
  3123.  
  3124. # scalar-tying package for output(print_to => *HANDLE) implementation
  3125. package HTML::Template::PRINTSCALAR;
  3126. use strict;
  3127.  
  3128. sub TIESCALAR { bless \$_[1], $_[0]; }
  3129. sub FETCH { }
  3130. sub STORE {
  3131.   my $self = shift;
  3132.   local *FH = $$self;
  3133.   print FH @_;
  3134. }
  3135. 1;
  3136. __END__
  3137.  
  3138. =head1 FREQUENTLY ASKED QUESTIONS
  3139.  
  3140. In the interest of greater understanding I've started a FAQ section of
  3141. the perldocs.  Please look in here before you send me email.
  3142.  
  3143. =over 4
  3144.  
  3145. =item 1
  3146.  
  3147. Q: Is there a place to go to discuss HTML::Template and/or get help?
  3148.  
  3149. A: There's a mailing-list for discussing HTML::Template at
  3150. html-template-users@lists.sourceforge.net.  To join:
  3151.  
  3152.    http://lists.sourceforge.net/lists/listinfo/html-template-users
  3153.  
  3154. If you just want to get email when new releases are available you can
  3155. join the announcements mailing-list here:
  3156.  
  3157.    http://lists.sourceforge.net/lists/listinfo/html-template-announce
  3158.     
  3159. =item 2
  3160.  
  3161. Q: Is there a searchable archive for the mailing-list?
  3162.  
  3163. A: Yes, you can find an archive of the SourceForge list here:
  3164.  
  3165.   http://www.geocrawler.com/lists/3/SourceForge/23294/0/
  3166.  
  3167. For an archive of the old vm.com list, setup by Sean P. Scanlon, see:
  3168.  
  3169.    http://bluedot.net/mail/archive/
  3170.  
  3171. =item 3
  3172.  
  3173. Q: I want support for <TMPL_XXX>!  How about it?
  3174.  
  3175. A: Maybe.  I definitely encourage people to discuss their ideas for
  3176. HTML::Template on the mailing list.  Please be ready to explain to me
  3177. how the new tag fits in with HTML::Template's mission to provide a
  3178. fast, lightweight system for using HTML templates.
  3179.  
  3180. NOTE: Offering to program said addition and provide it in the form of
  3181. a patch to the most recent version of HTML::Template will definitely
  3182. have a softening effect on potential opponents!
  3183.  
  3184. =item 4
  3185.  
  3186. Q: I found a bug, can you fix it?
  3187.  
  3188. A: That depends.  Did you send me the VERSION of HTML::Template, a test
  3189. script and a test template?  If so, then almost certainly.
  3190.  
  3191. If you're feeling really adventurous, HTML::Template has a publically
  3192. available Subversion server.  See below for more information in the PUBLIC
  3193. SUBVERSION SERVER section.
  3194.  
  3195. =item 5
  3196.  
  3197. Q: <TMPL_VAR>s from the main template aren't working inside a
  3198. <TMPL_LOOP>!  Why?
  3199.  
  3200. A: This is the intended behavior.  <TMPL_LOOP> introduces a separate
  3201. scope for <TMPL_VAR>s much like a subroutine call in Perl introduces a
  3202. separate scope for "my" variables.
  3203.  
  3204. If you want your <TMPL_VAR>s to be global you can set the
  3205. 'global_vars' option when you call new().  See above for documentation
  3206. of the 'global_vars' new() option.
  3207.  
  3208. =item 6
  3209.  
  3210. Q: Why do you use /[Tt]/ instead of /t/i?  It's so ugly!
  3211.  
  3212. A: Simple - the case-insensitive match switch is very inefficient.
  3213. According to _Mastering_Regular_Expressions_ from O'Reilly Press,
  3214. /[Tt]/ is faster and more space efficient than /t/i - by as much as
  3215. double against long strings.  //i essentially does a lc() on the
  3216. string and keeps a temporary copy in memory.
  3217.  
  3218. When this changes, and it is in the 5.6 development series, I will
  3219. gladly use //i.  Believe me, I realize [Tt] is hideously ugly.
  3220.  
  3221. =item 7
  3222.  
  3223. Q: How can I pre-load my templates using cache-mode and mod_perl?
  3224.  
  3225. A: Add something like this to your startup.pl:
  3226.  
  3227.    use HTML::Template;
  3228.    use File::Find;
  3229.  
  3230.    print STDERR "Pre-loading HTML Templates...\n";
  3231.    find(
  3232.         sub {
  3233.           return unless /\.tmpl$/;
  3234.           HTML::Template->new(
  3235.                               filename => "$File::Find::dir/$_",
  3236.                               cache => 1,
  3237.                              );
  3238.         },
  3239.         '/path/to/templates',
  3240.         '/another/path/to/templates/'
  3241.       );
  3242.  
  3243. Note that you'll need to modify the "return unless" line to specify
  3244. the extension you use for your template files - I use .tmpl, as you
  3245. can see.  You'll also need to specify the path to your template files.
  3246.  
  3247. One potential problem: the "/path/to/templates/" must be EXACTLY the
  3248. same path you use when you call HTML::Template->new().  Otherwise the
  3249. cache won't know they're the same file and will load a new copy -
  3250. instead getting a speed increase, you'll double your memory usage.  To
  3251. find out if this is happening set cache_debug => 1 in your application
  3252. code and look for "CACHE MISS" messages in the logs.
  3253.  
  3254. =item 8
  3255.  
  3256. Q: What characters are allowed in TMPL_* NAMEs?
  3257.  
  3258. A: Numbers, letters, '.', '/', '+', '-' and '_'.
  3259.  
  3260. =item 9
  3261.  
  3262. Q: How can I execute a program from inside my template?  
  3263.  
  3264. A: Short answer: you can't.  Longer answer: you shouldn't since this
  3265. violates the fundamental concept behind HTML::Template - that design
  3266. and code should be seperate.
  3267.  
  3268. But, inevitably some people still want to do it.  If that describes
  3269. you then you should take a look at
  3270. L<HTML::Template::Expr|HTML::Template::Expr>.  Using
  3271. HTML::Template::Expr it should be easy to write a run_program()
  3272. function.  Then you can do awful stuff like:
  3273.  
  3274.   <tmpl_var expr="run_program('foo.pl')">
  3275.  
  3276. Just, please, don't tell me about it.  I'm feeling guilty enough just
  3277. for writing HTML::Template::Expr in the first place.
  3278.  
  3279. =item 10
  3280.  
  3281. Q: Can I get a copy of these docs in Japanese?
  3282.  
  3283. A: Yes you can.  See Kawai Takanori's translation at:
  3284.  
  3285.    http://member.nifty.ne.jp/hippo2000/perltips/html/template.htm
  3286.  
  3287. =item 11
  3288.  
  3289. Q: What's the best way to create a <select> form element using
  3290. HTML::Template?
  3291.  
  3292. A: There is much disagreement on this issue.  My personal preference
  3293. is to use CGI.pm's excellent popup_menu() and scrolling_list()
  3294. functions to fill in a single <tmpl_var select_foo> variable.  
  3295.  
  3296. To some people this smacks of mixing HTML and code in a way that they
  3297. hoped HTML::Template would help them avoid.  To them I'd say that HTML
  3298. is a violation of the principle of separating design from programming.
  3299. There's no clear separation between the programmatic elements of the
  3300. <form> tags and the layout of the <form> tags.  You'll have to draw
  3301. the line somewhere - clearly the designer can't be entirely in charge
  3302. of form creation.
  3303.  
  3304. It's a balancing act and you have to weigh the pros and cons on each side.
  3305. It is certainly possible to produce a <select> element entirely inside the
  3306. template.  What you end up with is a rat's nest of loops and conditionals.
  3307. Alternately you can give up a certain amount of flexibility in return for
  3308. vastly simplifying your templates.  I generally choose the latter.
  3309.  
  3310. Another option is to investigate HTML::FillInForm which some have
  3311. reported success using to solve this problem.
  3312.  
  3313. =back
  3314.  
  3315. =head1 BUGS
  3316.  
  3317. I am aware of no bugs - if you find one, join the mailing list and
  3318. tell us about it.  You can join the HTML::Template mailing-list by
  3319. visiting:
  3320.  
  3321.   http://lists.sourceforge.net/lists/listinfo/html-template-users
  3322.  
  3323. Of course, you can still email me directly (sam@tregar.com) with bugs,
  3324. but I reserve the right to forward bug reports to the mailing list.
  3325.  
  3326. When submitting bug reports, be sure to include full details,
  3327. including the VERSION of the module, a test script and a test template
  3328. demonstrating the problem!
  3329.  
  3330. If you're feeling really adventurous, HTML::Template has a publically
  3331. available Subversion server.  See below for more information in the
  3332. PUBLIC SUBVERSION SERVER section.
  3333.  
  3334. =head1 CREDITS
  3335.  
  3336. This module was the brain child of my boss, Jesse Erlbaum
  3337. ( jesse@vm.com ) at Vanguard Media ( http://vm.com ) .  The most original
  3338. idea in this module - the <TMPL_LOOP> - was entirely his.
  3339.  
  3340. Fixes, Bug Reports, Optimizations and Ideas have been generously
  3341. provided by:
  3342.  
  3343.    Richard Chen
  3344.    Mike Blazer
  3345.    Adriano Nagelschmidt Rodrigues
  3346.    Andrej Mikus
  3347.    Ilya Obshadko
  3348.    Kevin Puetz
  3349.    Steve Reppucci
  3350.    Richard Dice
  3351.    Tom Hukins
  3352.    Eric Zylberstejn
  3353.    David Glasser
  3354.    Peter Marelas
  3355.    James William Carlson
  3356.    Frank D. Cringle
  3357.    Winfried Koenig
  3358.    Matthew Wickline
  3359.    Doug Steinwand
  3360.    Drew Taylor
  3361.    Tobias Brox
  3362.    Michael Lloyd
  3363.    Simran Gambhir
  3364.    Chris Houser <chouser@bluweb.com>
  3365.    Larry Moore
  3366.    Todd Larason
  3367.    Jody Biggs
  3368.    T.J. Mather
  3369.    Martin Schroth
  3370.    Dave Wolfe
  3371.    uchum
  3372.    Kawai Takanori
  3373.    Peter Guelich
  3374.    Chris Nokleberg
  3375.    Ralph Corderoy
  3376.    William Ward
  3377.    Ade Olonoh
  3378.    Mark Stosberg
  3379.    Lance Thomas
  3380.    Roland Giersig
  3381.    Jere Julian
  3382.    Peter Leonard
  3383.    Kenny Smith
  3384.    Sean P. Scanlon
  3385.    Martin Pfeffer
  3386.    David Ferrance
  3387.    Gyepi Sam  
  3388.    Darren Chamberlain
  3389.    Paul Baker
  3390.    Gabor Szabo
  3391.    Craig Manley
  3392.    Richard Fein
  3393.    The Phalanx Project
  3394.    Sven Neuhaus
  3395.  
  3396. Thanks!
  3397.  
  3398. =head1 WEBSITE
  3399.  
  3400. You can find information about HTML::Template and other related modules at:
  3401.  
  3402.    http://html-template.sourceforge.net
  3403.  
  3404. =head1 PUBLIC SUBVERSION SERVER
  3405.  
  3406. HTML::Template now has a publicly accessible Subversion server
  3407. provided by SourceForge (www.sourceforge.net).  You can access it by
  3408. going to http://sourceforge.net/svn/?group_id=1075.  Give it a try!
  3409.  
  3410. =head1 AUTHOR
  3411.  
  3412. Sam Tregar, sam@tregar.com
  3413.  
  3414. =head1 LICENSE
  3415.  
  3416.   HTML::Template : A module for using HTML Templates with Perl
  3417.   Copyright (C) 2000-2002 Sam Tregar (sam@tregar.com)
  3418.  
  3419.   This module is free software; you can redistribute it and/or modify it
  3420.   under the terms of either:
  3421.  
  3422.   a) the GNU General Public License as published by the Free Software
  3423.   Foundation; either version 1, or (at your option) any later version,
  3424.   
  3425.   or
  3426.  
  3427.   b) the "Artistic License" which comes with this module.
  3428.  
  3429.   This program is distributed in the hope that it will be useful,
  3430.   but WITHOUT ANY WARRANTY; without even the implied warranty of
  3431.   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See either
  3432.   the GNU General Public License or the Artistic License for more details.
  3433.  
  3434.   You should have received a copy of the Artistic License with this
  3435.   module, in the file ARTISTIC.  If not, I'll be glad to provide one.
  3436.  
  3437.   You should have received a copy of the GNU General Public License
  3438.   along with this program; if not, write to the Free Software
  3439.   Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
  3440.   USA
  3441.  
  3442. =cut
  3443.